作瞬态分析，报错，请高手指教

huazi071783

我做一个梁受一个余弦荷载作用，作瞬态分析，在梁上表面均匀提取17个节点的位移响应，出错：Error: Number of results on results file exceeds maximun of 1000, Maximun may be increased with/CONFIG command. 当我把作用力循环里荷载步的i值取1到100时或小于100就不会出错(命令流中红字显示)，但是这样荷载步太少，作用时间太少，我取大一点如1000时就不行了；
/PREP7                           
ET,1,SHELL63                     
!建模设定参数
l=1.0                             !梁长
h=0.01                           !梁高
b=0.03                            !梁宽
EX0=73E9
PRXY0=0.33
DENS0=2270
N0=80                             !梁长方向单元数
Nh=3                              !梁高方向单元数
f=20                               !作用力幅值
!生成节点
*DO, j, 1, Nh+1
  *DO, i, 1, N0+1
    N,i+(j-1)*(N0+1),(i-1)*l/N0,(j-1)*h/(Nh),0,,,,
  *ENDDO
*ENDDO
!生成单元
*DO,j,1,Nh
  *DO,i,1,N0
   E,i+(j-1)*(N0+1),i+1+(j-1)*(N0+1),i+1+j*(N0+1),i+j*(N0+1)
  *ENDDO
*ENDDO  
!单元厚度设定
R,1,b, , , , , ,              
RMORE, , , ,
RMORE   
RMORE, ,
!
!材料属性
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,EX0   
MPDATA,PRXY,1,,PRXY0  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,DENS,1,,DENS0
!施加约束，
/SOL
ANTYPE,4
TRNOPT,FULL
LUMPM,0
!
*do,i,1,Nh+1
   D,1+(i-1)*(N0+1), , , , , ,ALL, , , , ,  
*enddo
D,all, ,0, , , ,UZ, , , , ,
!º荷载步设定
!
timint,on,all                        ¡打开瞬态效应
alphad, 0.02                         ¡a阻尼
betad,0.004                          ¡beta阻尼
*do,i,1,1000
   time,0.1*i                           !作用时间点
  deltime,0.01                         !荷载步作用时间
   kbc,0                                !斜坡荷载
  LSWRITE, 1                          !写入荷载步
  f,(N0+1)*(Nh+1)-1,fy,-f*cos(20*i)      !作用余弦荷载
  OUTRES, all, all                     !结果输出频率设置
  solve
*enddo
finish
!提取结果
/POST26
*DIM,dis,array,10000,17
NUMVAR,100
!提取17个节点唯一响应
*do,i,1,17,1
j=i+1
N=(N0+1)*Nh+(i-1)*5+1
NSOL,j,N,U,Y   
*enddo
!        
*do,j,2,18,1   
VGET,dis(1,j-1),j
*enddo
!      
*CFOPEN,displace,TXT
*Vwrite,dis(1,1),dis(1,2),dis(1,3),dis(1,4),dis(1,5),dis(1,6),dis(1,7),dis(1,8),dis(1,9),dis(1,10),dis(1,11),dis(1,12),dis(1,13),dis(1,14),dis(1,15),dis(1,16),dis(1,17)
(17F8.5)
*CFCLOS

huazi071783

为什么荷载子步总数超过1000就出错啊？不知道在哪里改，盼解决

huazi071783

王新敏那本书上说是要用OUTRES设置结果输出频率控制，缺省时只写入荷载步的最后一个子步结果，特别地，缺省时当写入的结果数目超过1000时程序就出错终止，但是我设置了这个输出为全部荷载子步都输出，但还是提示这个错误，晕了

huazi071783

提示是说用/CONFIG,NERS,VALUE就可以解决，但是我把命令/CONFIG,NERS,10000放在施加力循环里面，提示：/CONFIG is not a recognized solution command, 放在/post26提取结果那里还是提示以前那个错误，咳，没高手指点，只能边试边自己回答

Chelsea

/CONFIG,NERS,VALUE应该放在/prep7之前

huazi071783

回复 5 # Chelsea 的帖子

谢谢，我试试看先

huazi071783

回复 5 # Chelsea 的帖子

解决，谢谢，就是你说的那样