ansys中杆梁壳体单元耦合问题

sorry

　　一般来说，按“杆梁壳体”单元顺序，只要后一种单元的自由度完全包含前一种单元的自由度，则只要有公共节点即可，不需要约束方程，否则需要耦合自由度与约事方程。

　　例如：

　　(1)杆与梁、壳、体单元有公共节点即可，不需要约束方程。

　　(2)梁与壳有公共节点即可，也不需要约束写约束方程;壳梁自由度数目相同，自由度也相同，尽管壳的rotz是虚的自由度，也不妨碍二者之间的关系，这有点类同于梁与杆的关系。

　　(3)梁与体则要在相同位置建立不同的节点 ，然后在节点处耦合自由度与施加约束方程。

　　(4)壳与体则也要相同位置建立不同的节点 ，然后在节点处耦合自由度与施加约束方程。

　　举例：

　　有一长为100mm的矩形截面梁，截面为10X1mm，与一规格为20mmX7mmX10mm的实体连接，约束实体的端面，在梁端施加大小为3N的y方向的压力，梁与实体都为一材料 ，弹性模量为30Gpa，泊松比为0.3。本例主要讲解梁与实体连接处如何利用耦合及约束方程进行处理。

　　命令流如下：

　　FINI

　　/CLE

　　/FILNAME,BEAM_AND_SOLID_ELEMENTS_CONNECTION !定义工作文件名

　　/TITLE,COUPLE_AND_CONSTRAINT_EQUATION !定义工作名

　　/PREP7

　　ET,1,SOLID95 !定义实体单元类型为SOLID95

　　ET,2,BEAM4 !定义梁单元类型为BEAM4

　　MP,EX,1,3E4 !定义材料的弹性模量

　　MP,PRXY,1,0.3 !定义泊松比

　　R,1 !定义实体单元实常数

　　R,2,10.0,10/12.0,1000/12.0,10.0,1.0 !定义梁单元实常数

　　BLC4,,,20,7,10 !创建矩形块为实体模型

　　WPOFFS,0,3.5 !将工作平面向Y方向移动3.5

　　WPROTA,0,90 !将工作平面绕X轴旋转90度

　　VSBW,ALL !将实体沿工作平面剖开

　　WPOFFS,0,5 !将工作平面向Y方向移动5

　　WPROTA,0,90 !将工作平面绕X轴旋转90度

　　VSBW,ALL !将实体沿工作平面剖开

　　WPCSYS,-1 !将工作平面设为与总体笛卡儿坐标一致

　　K,100,20,3.5,5 !创建关键点

　　K,101,120,3.5,5 !创建关键点

　　L,100,101 !连接关键点生成梁的线实体

　　LSEL,S,LOC,X,21,130 !选择梁线

　　LATT,1,2,2 !指定梁的单元属性

　　LESIZE,ALL,,,10 !指定梁上的单元份数

　　LMESH,ALL !划分梁单元

　　VSEL,ALL !选择所有实体

　　VATT,1,1,1 !设置实体的单元属性

　　ESIZE,1 !指定实体单元尺寸

　　MSHAPE,0,2D !设置实体单元为2D

　　MSHKEY,1 !设置为映射网格划分方法

　　VMESH,ALL !划分实体单元

　　ALLS !全选

　　FINI !退出前处理

　　!------------------------

　　/SOLU !进入求解器

　　ASEL,S,LOC,X,0 !选择实体的端面

　　DA,ALL,ALL !约束实体端面

　　ALLS !全选

　　FK,101,FY,-3.0 !在两端施加Y向压力

　　CP,1,UX,1,21 !耦合节点1和节点21X方向自由度

　　CP,2,UY,1,21 !耦合节点1和节点21Y方向自由度

　　CP,3,UZ,1,21 !耦合节点1和节点21Z方向自由度

　　CE,1,0,626,UX,1,2328,UX,-1,1,ROTY,-ABS(NZ(626)-NZ(2328)) !设置约束方程

　　CE,2,0,67,UX,1,4283,UX,-1,1,ROTZ,-ABS(NY(67)-NY(4283)) !设置约束方程

　　CE,3,0,67,UZ,1,4283,UZ,-1,1,ROTX,-ABS(NY(67)-NY(4283)) !设置约束方程

　　ALLS !全选

　　SOLVE !保存

　　FINI !退出求解器

　　!------------------------

　　/POST1 !进入通用后处理

　　PLNSOL, U,Y, 0,1.0 !显示Y方向位移

　　PLNSOL, S,EQV, 0,1.0 !显示等效应力

　　ETABLE,ZL1,SMISC,1 !读取梁单元上I节点X方向的力

　　ETABLE,ZL2,SMISC,7 !读取梁单元上J节点X方向的力

　　ETABLE,MZ1,SMISC,6 !读取梁单元上I节点Z方向的力矩

　　ETABLE,MZ2,SMISC,12 !读取梁单元上J节点Z方向的力矩

　　PLETAB,ZL1 !显示梁单元X方向的力

　　PLETAB,MZ1 !显示梁单元Z方向力矩

　　!**********************************************

　　上面所述的不同单元之间的接连方法主要是用耦合自由度和约束方程来实现的，有一定的局限性，只适用于小位移，下面介绍一种支持大位移算法的方法，MPC法。

　　MPC即Multipoint Constraint,多点约束方程，其原理与前面所说的方程的技术几乎一致，将不连续、自由度不协调的单元网格连接起来，不需要连接边界上的节点完全一一对应。

　　MPC能够连接的模型一般有以下几种。

　　solid 模型-solid 模型

　　shell模型-shell模型

　　solid 模型-shell 模型

　　solid 模型-beam 模型

　　shell 模型-beam模型

　　在 ANSYS中，实现上述MPC技术有三种途径。

　　(1)通过MPC184单元定义模型的刚性或者二力杆连接关系。定义MPC184单元模型与定义杆的操作完全一致，而MPC单元的作用可以是刚性杆(三个自由度的连接关系)或者刚性梁(六个自由度的连接关系)。

　　(2)利用约束方程菜单路径Main Menu>preprocessor>Coupling/Ceqn>shell/solid Interface创建壳与实体模型之间的装配关系。

　　(3)利用ANSYS接触向导功能定义模型之间的装配关系。选择菜单路径Main Menu>preprocessor>Modeling>Creat>Contact Pair，弹出一序列的接触向导对话框，按照提示进行操作，在创建接触对前，单击Optional setting按钮弹出Contact properties对话框，将Basic选项卡中的Contact algorithm即接触算法设置为MPC algorithm。或者，在定义完接触对后，再将接触算法修改为MPC algorithm，就相当于定义MPC多点约束关系进行多点约束算法。



转自：http://blog.sina.com.cn/s/blog_3ffb65190100qb3r.html