三维的隧道开挖实例

AaronSpark

FINI
/CLE
/FILENAME,'TUNNEL'
/UNIT,SI
/CONFIG,NRES,1E6
!--------------------------------------------------------------------------------------------------------------------!
!*
TM_YS=16*1E9      
MU_YS=0.24         
C_YS=1.80*1E6      
FI_YS=43           
MD_YS=0.027*1E6/10
!*
!*C20
TM_GXW=26*1E9      
MU_GXW=0.21        
C_GXW=2.4*1E6      
FI_GXW=50           
MD_GXW=0.02235*1E6/10
!*
!* C10*!
TM_HNT=22*1E9      
MU_HNT=0.20        
C_HNT=1.73*1E6      
FI_HNT=49           
MD_HNT=0.024*1E6/10
!*
TM_MG=TM_YS      
MU_MG=MU_YS         
MD_MG=MD_YS         
NT_MG=90*1E3         
C_MG=C_YS*1.10        
FI_MG=FI_YS+5         
ZH_MG=NT_MG/(1.2*1*1)
!----------------------------------------------------------------------------------------------------------------------!
!*
R_HJ=6.230           
H_ZQ=2.670           
L_ZTZ=40            
L_YTZ=40            
Y_YJMIN=400         
Y_YJMAX=415         
L_YJ=Y_YJMAX-Y_YJMIN
L_MG=3.5            
JJ_MG=5.0            
PJ_MG=5.0           
H_CENDB=1.47         
PD=2/1000            
W_GXW=0.2            
H_JS=831            
DMJL_SD=40           
H_CTOB=1.47         
*DIM,CEN_ZSD,ARRAY,2,1
*DIM,CEN_YSD,ARRAY,2,1
CEN_ZSD(1,1)=-DMJL_SD/2,880
CEN_YSD(1,1)=DMJL_SD/2,880 !+H_CTOB
H_ZQ=2.67               
FLAG_RD=3           
JL_RD=5              
*DIM,Z_RDCC,ARRAY,3,2
Z_RDCC(1,1)=3,3,3
Z_RDCC(1,2)=CEN_ZSD(1,1),CEN_ZSD(2,1)+R_HJ+JL_RD+Z_RDCC(2,1)/2,L_ZTZ+7.5
*DIM,Y_RDCC,ARRAY,3,2
Y_RDCC(1,1)=3,3,3
Y_RDCC(1,2)=CEN_YSD(1,1),CEN_YSD(2,1)+R_HJ+JL_RD+Y_RDCC(2,1)/2,L_ZTZ+7.5
!*
*DIM,DBKZDX,ARRAY,9,1
*DIM,DBKZDZ,ARRAY,(Y_YJMAX-Y_YJMIN)/PJ_MG+3,1
DBKZDX(1,1)=-150,-64,-38,-20,0,20,42,64,150  
DBKZDZ(1,1)=0,L_ZTZ
DBKZDZ((Y_YJMAX-Y_YJMIN)/PJ_MG+3,1)=L_ZTZ+Y_YJMAX-Y_YJMIN+L_YTZ
*DO,I,1,(Y_YJMAX-Y_YJMIN)/PJ_MG
        DBKZDZ(I+2,1)=L_ZTZ+PJ_MG*I
*ENDDO
*DIM,DBKZDGC,ARRAY,9,(Y_YJMAX-Y_YJMIN)/PJ_MG+3
DBKZDGC(1,1)=929,915,915,920,925,930,937,940,940
DBKZDGC(1,2)=929,915,915,920,925,930,937,940,940
DBKZDGC(1,3)=929,915,915,920,925,930,937,940,940
DBKZDGC(1,4)=929,915,915,920,925,930,937,940,940
DBKZDGC(1,5)=929,915,915,920,925,930,937,940,940
DBKZDGC(1,6)=929,915,915,920,925,930,937,940,940
!*************************************************************************************!
!*
!----------------------------------------------------------------------------------------------------------------------!
/PREP7
ET,1,95
ET,2,43
KEYOPT,2,5,2
R,1,W_GXW

MP,EX,7,TM_YS
MP,PRXY,7,MU_YS
MP,DENS,7,MD_YS
MP,EX,1,TM_YS
MP,PRXY,1,MU_YS
MP,DENS,1,MD_YS
MP,EX,2,TM_GXW
MP,PRXY,2,MU_GXW
MP,DENS,2,MD_GXW
MP,EX,3,TM_MG
MP,PRXY,3,MU_MG
MP,DENS,3,MD_MG
MP,EX,4,TM_HNT
MP,PRXY,4,MU_HNT
MP,DENS,4,MD_HNT
MP,EX,5,TM_YS
MP,PRXY,5,MU_YS
MP,DENS,5,MD_YS
MP,EX,6,TM_YS
MP,PRXY,6,MU_YS
TB,DP,1,,,  
TBMODIF,1,1,C_YS   
TBMODIF,1,2,FI_YS     
TB,DP,2,,,  
TBMODIF,1,1,C_GXW   
TBMODIF,1,2,FI_GXW     
TB,DP,3,,,  
TBMODIF,1,1,C_MG   
TBMODIF,1,2,FI_MG      
TB,DP,4,,,  
TBMODIF,1,1,C_HNT   
TBMODIF,1,2,FI_HNT   
TB,DP,5,,,  
TBMODIF,1,1,C_YS   
TBMODIF,1,2,FI_YS  
TB,DP,6,,,  
TBMODIF,1,1,C_YS   
TBMODIF,1,2,FI_YS
!**************************************************!
MAT_YS=1   
MAT_GXW=2
MAT_MG=3
MAT_DB=4
MAT_SD=5
MAT_MGKW=6
MAT_TXYS=1  
KBEGIN=0
*DO,I,1,9-1
        *DO,J,1,(Y_YJMAX-Y_YJMIN)/PJ_MG+3-1       
                K,KBEGIN+1,DBKZDX(I,1),H_JS,DBKZDZ(J,1)
                K,KBEGIN+2,DBKZDX(I,1),DBKZDGC(I,J),DBKZDZ(J,1)
                K,KBEGIN+3,DBKZDX(I,1),DBKZDGC(I,J+1),DBKZDZ(J+1,1)
                K,KBEGIN+4,DBKZDX(I,1),H_JS,DBKZDZ(J+1,1)
               
                K,KBEGIN+5,DBKZDX(I+1,1),H_JS,DBKZDZ(J,1)
                K,KBEGIN+6,DBKZDX(I+1,1),DBKZDGC(I+1,J),DBKZDZ(J,1)
                K,KBEGIN+7,DBKZDX(I+1,1),DBKZDGC(I+1,J+1),DBKZDZ(J+1,1)
                K,KBEGIN+8,DBKZDX(I+1,1),H_JS,DBKZDZ(J+1,1)
                V,KBEGIN+1,KBEGIN+2,KBEGIN+3,KBEGIN+4,KBEGIN+5,KBEGIN+6,KBEGIN+7,KBEGIN+8

                KBEGIN=KBEGIN+8
        *ENDDO
*ENDDO
ALLS
VGLUE,ALL
NUMCMP,ALL
VATT,MAT_YS  
!*
CYL4,CEN_ZSD(1,1),CEN_ZSD(2,1),R_HJ+L_MG,180,,,L_ZTZ+L_YTZ+Y_YJMAX-Y_YJMIN
CYL4,CEN_YSD(1,1),CEN_YSD(2,1),R_HJ+L_MG,180,,,L_ZTZ+L_YTZ+Y_YJMAX-Y_YJMIN
BLOCK,CEN_ZSD(1,1)-R_HJ-L_MG,CEN_ZSD(1,1)+R_HJ+L_MG,CEN_ZSD(2,1)-H_ZQ,CEN_ZSD(2,1),DBKZDZ(1,1),DBKZDZ((Y_YJMAX-Y_YJMIN)/PJ_MG+3,1)
BLOCK,CEN_YSD(1,1)-R_HJ-L_MG,CEN_YSD(1,1)+R_HJ+L_MG,CEN_YSD(2,1)-H_ZQ,CEN_YSD(2,1),DBKZDZ(1,1),DBKZDZ((Y_YJMAX-Y_YJMIN)/PJ_MG+3,1)
!*
VSEL,ALL
VSEL,S,MAT,,MAT_YS
CM,V_BSUB,VOLU      
VSEL,INVE           
CM,V_SUB,VOLU
ALLS
VSBV,V_BSUB,V_SUB
CMDEL,V_BSUB         
CMDEL,V_SUB
ALLS
NUMCMP,ALL
VATT,MAT_YS   
!*
*DO,I,1,(Y_YJMAX-Y_YJMIN)/PJ_MG+3-1
        WPAVE,CEN_ZSD(1,1),CEN_ZSD(2,1),DBKZDZ(I,1)
        CYL4,0,0,R_HJ+L_MG,180,R_HJ,,DBKZDZ(I+1,1)-DBKZDZ(I,1)      
        CYL4,0,0,R_HJ,180,,,DBKZDZ(I+1,1)-DBKZDZ(I,1)               
        BLOCK,-R_HJ,R_HJ,-H_CTOB,0,0,DBKZDZ(I+1,1)-DBKZDZ(I,1)      
        BLOCK,-R_HJ,R_HJ,-H_ZQ,-H_CTOB,0,DBKZDZ(I+1,1)-DBKZDZ(I,1)   
        BLOCK,-R_HJ-L_MG,-R_HJ,-H_ZQ,0,0,DBKZDZ(I+1,1)-DBKZDZ(I,1)   
        BLOCK,R_HJ,R_HJ+L_MG,-H_ZQ,0,0,DBKZDZ(I+1,1)-DBKZDZ(I,1)     
        WPAVE,CEN_YSD(1,1),CEN_YSD(2,1),DBKZDZ(I,1)
        CYL4,0,0,R_HJ+L_MG,180,R_HJ,,DBKZDZ(I+1,1)-DBKZDZ(I,1)      
        CYL4,0,0,R_HJ,180,,,DBKZDZ(I+1,1)-DBKZDZ(I,1)               
        BLOCK,-R_HJ,R_HJ,-H_CTOB,0,0,DBKZDZ(I+1,1)-DBKZDZ(I,1)      
        BLOCK,-R_HJ,R_HJ,-H_ZQ,-H_CTOB,0,DBKZDZ(I+1,1)-DBKZDZ(I,1)   
        BLOCK,-R_HJ-L_MG,-R_HJ,-H_ZQ,0,0,DBKZDZ(I+1,1)-DBKZDZ(I,1)   
        BLOCK,R_HJ,R_HJ+L_MG,-H_ZQ,0,0,DBKZDZ(I+1,1)-DBKZDZ(I,1)     
*ENDDO

ALLS
VGLUE,ALL   
NUMCMP,ALL
CM,ROCK,VOLU

WPAVE,0,0,0
*IF,FLAG_RD,EQ,-1,OR,FLAG_RD,EQ,2,THEN
        VSTART=1000
        NUMSTR,VOLU,VSTART
        BLOCK,Z_RDCC(1,2)-Z_RDCC(1,1)/2,Z_RDCC(1,2)+Z_RDCC(1,1)/2,Z_RDCC(2,2)-Z_RDCC(2,1)/2,Z_RDCC(2,2)+Z_RDCC(2,1)/2,Z_RDCC(3,2)-Z_RDCC(3,1)/2,Z_RDCC(3,2)+Z_RDCC(3,1)/2
        VSBV,ROCK,VSTART
        NUMCMP,VOLU
        ALLS
        CMDEL,ROCK
        CM,ROCK,VOLU
*ENDIF
*IF,FLAG_RD,EQ,1,OR,FLAG_RD,EQ,2,THEN
        VSTART=1000
        NUMSTR,VOLU,VSTART
        BLOCK,Y_RDCC(1,2)-Y_RDCC(1,1)/2,Y_RDCC(1,2)+Y_RDCC(1,1)/2,Y_RDCC(2,2)-Y_RDCC(2,1)/2,Y_RDCC(2,2)+Y_RDCC(2,1)/2,Y_RDCC(3,2)-Y_RDCC(3,1)/2,Y_RDCC(3,2)+Y_RDCC(3,1)/2
        VSBV,ROCK,VSTART
        NUMCMP,VOLU
        ALLS
        CMDEL,ROCK
        CM,ROCK,VOLU
*ENDIF
ALLS
NUMCMP,ALL
!*
!----------------------------------------------------------------------------------------------------------------------!
!*
ALLS
VATT,MAT_YS
ALLS
VSEL,S,LOC,X,CEN_ZSD(1,1)-1E-7,CEN_ZSD(1,1)+1E-7         
CM,CM_TEMPV,VOLU
ASLV,R
ASEL,R,LOC,Y,CEN_ZSD(2,1)-H_ZQ-1E-7,CEN_ZSD(2,1)-H_ZQ+1E-7   
VSLA,R
CM,CM_ZDB,VOLU                                          
CMSEL,S,CM_TEMPV
ASLV,S
ASEL,R,LOC,Y,CEN_ZSD(2,1)-1E-7,CEN_ZSD(2,1)+1E-7         
ASEL,U,LOC,X,CEN_ZSD(1,1)-R_HJ,CEN_ZSD(1,1)-R_HJ-L_MG   
ASEL,U,LOC,X,CEN_ZSD(1,1)+R_HJ,CEN_ZSD(1,1)+R_HJ+L_MG
VSLA,R
CM,CM_ZSD,VOLU                                          
CMSEL,S,CM_ZSD
CMSEL,A,CM_ZDB
VATT,MAT_SD
CM,CM_ZSDKW,VOLU                                       
ALLS
CMSEL,S,CM_TEMPV
VSEL,U,MAT,,MAT_SD                                       
ASLV,R
ASEL,R,LOC,Y,CEN_ZSD(2,1)
VSEL,ALL
VSLA,R
VATT,MAT_MGKW
CM,CM_ZMG,VOLU                                          
!右隧道
ALLS
VSEL,S,LOC,X,CEN_YSD(1,1)-1E-7,CEN_YSD(1,1)+1E-7         
CM,CM_TEMPV,VOLU
ASLV,R
ASEL,R,LOC,Y,CEN_YSD(2,1)-H_ZQ-1E-7,CEN_YSD(2,1)-H_ZQ+1E-7   
VSLA,R
CM,CM_YDB,VOLU                                          
CMSEL,S,CM_TEMPV
ASLV,S
ASEL,R,LOC,Y,CEN_YSD(2,1)-1E-7,CEN_YSD(2,1)+1E-7         
ASEL,U,LOC,X,CEN_YSD(1,1)-R_HJ,CEN_YSD(1,1)-R_HJ-L_MG     
ASEL,U,LOC,X,CEN_YSD(1,1)+R_HJ,CEN_YSD(1,1)+R_HJ+L_MG
VSLA,R
CM,CM_YSD,VOLU                                            
CMSEL,S,CM_YSD
CMSEL,A,CM_YDB
VATT,MAT_SD
CM,CM_YSDKW,VOLU                                       
ALLS
CMSEL,S,CM_TEMPV
VSEL,U,MAT,,MAT_SD                                    
ASLV,R
ASEL,R,LOC,Y,CEN_YSD(2,1)
VSEL,ALL
VSLA,R
VATT,MAT_MGKW
CM,CM_YMG,VOLU                                          

ALLS

CMDEL,CM_TEMPV
ALLS
ASEL,S,LOC,X,DBKZDX(1,1)
ASEL,A,LOC,X,DBKZDX(9,1)
DA,ALL,UX,0        
ALLS
ASEL,S,LOC,Z,DBKZDZ(1,1)
ASEL,A,LOC,Z,DBKZDZ((Y_YJMAX-Y_YJMIN)/PJ_MG+3,1)
DA,ALL,UZ,0      
ALLS
ASEL,S,LOC,Y,H_JS
DA,ALL,ALL         
ALLS

LTS_ZD=2
LTS_YD=2
*DIM,ZLT_HFX,ARRAY,LTS_ZD,1
ZLT_HFX(1,1)=5,3 !4,2
*DIM,YLT_HFX,ARRAY,LTS_YD,1
YLT_HFX(1,1)=5,3 !4,2
*DIM,LT_HFZ,ARRAY,(Y_YJMAX-Y_YJMIN)/PJ_MG+2
LT_HFZ(1,1)=4                  
*DO,I,2,(Y_YJMAX-Y_YJMIN)/PJ_MG+1   
        LT_HFZ(I,1)=2 !PJ_MG
*ENDDO
LT_HFZ((Y_YJMAX-Y_YJMIN)/PJ_MG+2,1)=4 !10

*DO,J,1,LTS_ZD
        *DO,I,1,(Y_YJMAX-Y_YJMIN)/PJ_MG+3-1
                X_VCEN=(DBKZDX(J,1)+DBKZDX(J+1,1))/2
                Z_VCEN=(DBKZDZ(I,1)+DBKZDZ(I+1,1))/2
                VSEL,S,LOC,X,X_VCEN-1E-7,X_VCEN+1E-7
                VSEL,R,LOC,Z,Z_VCEN-1E-7,Z_VCEN+1E-7
                ASLV,R
                LSLA,R
                CM,CM_HFX,LINE
                LSEL,R,LOC,X,X_VCEN         
                LESIZE,ALL,,,ZLT_HFX(J,1),,1
                CMSEL,S,CM_HFX
                LSEL,R,LOC,Z,Z_VCEN
                LESIZE,ALL,,,LT_HFZ(I,1),,1
                CMSEL,S,CM_HFX
                LSEL,U,LOC,X,X_VCEN
                LSEL,U,LOC,Z,Z_VCEN
                LESIZE,ALL,,,9,,1   
                CMSEL,S,CM_HFX
                MSHAPE,0,3D
                MSHKEY,1
                VMESH,ALL
                ALLS
        *ENDDO
        !右端
        *DO,I,1,(Y_YJMAX-Y_YJMIN)/PJ_MG+3-1
                X_VCEN=(DBKZDX(9-J+1,1)+DBKZDX(9-J,1))/2
                Z_VCEN=(DBKZDZ(I,1)+DBKZDZ(I+1,1))/2
                VSEL,S,LOC,X,X_VCEN-1E-7,X_VCEN+1E-7
                VSEL,R,LOC,Z,Z_VCEN-1E-7,Z_VCEN+1E-7
                ASLV,R
                LSLA,R
                CM,CM_HFX,LINE
                LSEL,R,LOC,X,X_VCEN           
                LESIZE,ALL,,,YLT_HFX(J,1),,1
                CMSEL,S,CM_HFX
                LSEL,R,LOC,Z,Z_VCEN
                LESIZE,ALL,,,LT_HFZ(I,1),,1
                CMSEL,S,CM_HFX
                LSEL,U,LOC,X,X_VCEN
                LSEL,U,LOC,Z,Z_VCEN
                LESIZE,ALL,,,10,,1  
                CMSEL,S,CM_HFX
                MSHAPE,0,3D
                MSHKEY,1
                VMESH,ALL
                ALLS
        *ENDDO

*ENDDO
*DO,I,1,(Y_YJMAX-Y_YJMIN)/PJ_MG+3-1
        CMSEL,S,CM_ZSDKW
        ASLV,R
        LSLA,R

        X_VCEN=CEN_ZSD(1,1)
        Z_VCEN=(DBKZDZ(I,1)+DBKZDZ(I+1,1))/2
        VSEL,R,LOC,Z,Z_VCEN-1E-7,Z_VCEN+1E-7
        CM,CM_VMESH,VOLU
        ASLV,R
        LSLA,R
        CM,CM_HFX,LINE
        ALLS
       
        CMSEL,S,CM_HFX
        LSEL,R,LOC,X,X_VCEN-1E-7,X_VCEN-R_HJ+1E-7         
        LESIZE,ALL,,,2,,1   
        CMSEL,S,CM_HFX
        LSEL,R,LOC,X,X_VCEN+1E-7,X_VCEN+R_HJ-1E-7         
        LESIZE,ALL,,,2,,1      
        ALLS

        CMSEL,S,CM_HFX
        LSEL,R,LOC,X,X_VCEN-1E-7,X_VCEN+1E-7
        LSEL,U,LOC,Z,Z_VCEN
        LESIZE,ALL,2           
        ALLS
       
        CMSEL,S,CM_HFX
        LSEL,R,LOC,Z,Z_VCEN   
        LESIZE,ALL,,,LT_HFZ(I,1),,1
        ALLS

        CMSEL,S,CM_HFX
        LSEL,U,LOC,X,X_VCEN
        LSEL,U,LOC,X,X_VCEN-1E-7,X_VCEN-R_HJ+1E-7
        LSEL,U,LOC,X,X_VCEN+1E-7,X_VCEN+R_HJ-1E-7
        LSEL,U,LOC,Z,Z_VCEN
        LESIZE,ALL,,,1,,1   
        ALLS

        ALLS
        CMSEL,S,CM_VMESH
        MSHAPE,0,3D
        VSWEEP,ALL
        ALLS
*ENDDO


CMSEL,S,CM_ZMG
ESIZE,2  
VSWEEP,ALL
ALLS
*DO,I,1,(Y_YJMAX-Y_YJMIN)/PJ_MG+3-1
        CMSEL,S,CM_YSDKW
        ASLV,R
        LSLA,R

        X_VCEN=CEN_YSD(1,1)
        Z_VCEN=(DBKZDZ(I,1)+DBKZDZ(I+1,1))/2
        VSEL,R,LOC,Z,Z_VCEN-1E-7,Z_VCEN+1E-7
        CM,CM_VMESH,VOLU
        ASLV,R
        LSLA,R
        CM,CM_HFX,LINE
       
        CMSEL,S,CM_HFX
        LSEL,R,LOC,X,X_VCEN-1E-7,X_VCEN-R_HJ+1E-7         
        LESIZE,ALL,,,2,,1     
        CMSEL,S,CM_HFX
        LSEL,R,LOC,X,X_VCEN+1E-7,X_VCEN+R_HJ-1E-7         
        LESIZE,ALL,,,2,,1      

        CMSEL,S,CM_HFX
        LSEL,R,LOC,X,X_VCEN-1E-7,X_VCEN+1E-7
        LSEL,U,LOC,Z,Z_VCEN
        LSEL,U,LOC,Y,CEN_YSD(2,1)-H_CTOB                    
        LESIZE,ALL,2        
       
        CMSEL,S,CM_HFX
        LSEL,R,LOC,Z,Z_VCEN   
        LESIZE,ALL,,,LT_HFZ(I,1),,1

        CMSEL,S,CM_HFX
        LSEL,U,LOC,X,X_VCEN
        LSEL,U,LOC,X,X_VCEN-1E-7,X_VCEN-R_HJ+1E-7
        LSEL,U,LOC,X,X_VCEN+1E-7,X_VCEN+R_HJ-1E-7
        LSEL,U,LOC,Z,Z_VCEN
        LESIZE,ALL,,,1,,1     
       
        ALLS
        CMSEL,S,CM_VMESH
        MSHAPE,0,3D
        VSWEEP,ALL
        ALLS
       

        CMSEL,S,CM_YMG
        ESIZE,2  
        VSEL,R,LOC,Z,Z_VCEN-1E-7,Z_VCEN+1E-7
        VSWEEP,ALL
        ALLS
*ENDDO



ALLS
VSEL,U,MAT,,MAT_SD
VSEL,U,MAT,,MAT_MGKW
VSEL,R,LOC,X,DBKZDX(LTS_ZD+1,1),DBKZDX(9-LTS_YD,1)
CM,CM_VMESH,VOLU

!*
VSEL,S,,,CM_VMESH
VSEL,R,LOC,X,DBKZDX(LTS_ZD+1,1),DBKZDX(LTS_ZD+2,1)   
ASLV,S
LSLA,S
LSEL,R,LOC,X,(DBKZDX(LTS_ZD+1,1)+DBKZDX(LTS_ZD+2,1))/2
LESIZE,ALL,,,5   
!*
VSEL,S,,,CM_VMESH
VSEL,R,LOC,X,DBKZDX(LTS_ZD+2,1),DBKZDX(LTS_ZD+3,1)
ASLV,S
LSLA,S
LSEL,R,LOC,X,(DBKZDX(LTS_ZD+2,1)+DBKZDX(LTS_ZD+3,1))/2
LESIZE,ALL,,,3   
ALLS
!*
VSEL,S,,,CM_VMESH
VSEL,R,LOC,X,DBKZDX(LTS_ZD+3,1),DBKZDX(LTS_ZD+4,1)  
ASLV,S
LSLA,S
LSEL,R,LOC,X,(DBKZDX(LTS_ZD+3,1)+DBKZDX(LTS_ZD+4,1))/2
LESIZE,ALL,,,3   
!*
VSEL,S,,,CM_VMESH
VSEL,R,LOC,X,DBKZDX(LTS_ZD+4,1),DBKZDX(LTS_ZD+5,1)  
ASLV,S
LSLA,S
LSEL,R,LOC,X,(DBKZDX(LTS_ZD+4,1)+DBKZDX(LTS_ZD+5,1))/2
LESIZE,ALL,,,5   
ALLS
!*
ALLS
*DO,I,1,(Y_YJMAX-Y_YJMIN)/PJ_MG+3-1
        !CMSEL,S,CM_VMESH
        VSEL,S,,,CM_VMESH
        VSEL,R,LOC,Z,DBKZDZ(I,1),DBKZDZ(I+1,1)
        VSEL,R,LOC,X,DBKZDX(LTS_ZD+1,1),DBKZDX(LTS_ZD+3,1)
        CM,CM_NEXTV,VOLU

        CMSEL,S,CM_NEXTV
        ESIZE,4
        VSWEEP,ALL
        ALLS
*ENDDO

ALLS
LSEL,S,LOC,X,Y_RDCC(1,2)-Y_RDCC(1,1)/2-1E-7,Y_RDCC(1,2)+Y_RDCC(1,1)/2+1E-7
LSEL,R,LOC,Y,Y_RDCC(2,2)-Y_RDCC(2,1)/2-1E-7,Y_RDCC(2,2)+Y_RDCC(2,1)/2+1E-7
LSEL,R,LOC,Z,Y_RDCC(3,2)-Y_RDCC(3,1)/2-1E-7,Y_RDCC(3,2)+Y_RDCC(3,1)/2+1E-7
LESIZE,ALL,1   
ALLS


*DO,I,1,(Y_YJMAX-Y_YJMIN)/PJ_MG+3-1
        VSEL,S,,,CM_VMESH
        VSEL,R,LOC,Z,DBKZDZ(I,1),DBKZDZ(I+1,1)
        CM,CM_NEXTV,VOLU

        CMSEL,S,CM_NEXTV
        VSEL,R,LOC,X,DBKZDX(LTS_ZD+3,1),DBKZDX(LTS_ZD+3+2,1)
        ESIZE,4
        VSWEEP,ALL
        ALLS
*ENDDO
ALLS

VSEL,S,,,CM_ZSDKW   
ASLV,R
VSEL,S,,,CM_ZMG
ASLV,R
CM,CM_ZGXW,AREA
TYPE,2
MAT,MAT_GXW
AMESH,ALL
ALLS

VSEL,S,,,CM_YSDKW   
ASLV,R
VSEL,S,,,CM_YMG
ASLV,R
CM,CM_YGXW,AREA
TYPE,2
MAT,MAT_GXW
AMESH,ALL
ALLS

NUMCMP,ALL
ALLS
MPCHG,MAT_TXYS,ALL
ALLS

SAVE,TNLMESH,DB  
!------------------------------------------------------- 开始求解 ---------------------------------------!
/SOLU
!*
ACEL,,9.8
ANTYPE,STATIC,NEW
TIME,1     
NROPT,FULL
AUTOTS,ON  
DELTIM,0.5,0.01,0.5
LNSRCH,ON  
PRED,ON   
ISWRITE,1
ALLS
!*
ALLS
ESEL,S,TYPE,,2
EKILL,ALL
!*
ALLS
SOLV
FINI
!*

/CLE
/FILNAME,CALTUN
/PREP7
RESUME,TNLMESH,DB
FINI
!*
/SOLU
!*
ACEL,,9.8
!*
ANTYPE,STATIC,NEW
TIME,1         
NROPT,FULL
AUTOTS,ON  
DELTIM,0.5,0.01,0.5
LNSRCH,ON  
PRED,ON   
ESEL,U,TYPE,,2
ISFILE,READ,TUNNEL,IST,,0
!*
ALLS
ESEL,S,TYPE,,2
EKILL,ALL!*
CNVTOL,F,0.05
ALLS
!*
SOLV

!---------------------------------------------------------------------- 开挖模拟 ---------------------------------------------------!
!-----------------------------------    第一步开挖，这一步没有支护     ----------------------------------!
ALLS
VSEL,S,,,CM_ZSDKW
VSEL,A,,,CM_YSDKW
VSEL,R,LOC,Z,DBKZDZ(1,1),DBKZDZ(2,1)
ESLV,R
!ESEL,A,TYPE,,2
EKILL,ALL  
TIME,2     
NROPT,FULL
AUTOTS,ON  
DELTIM,0.3,0.001,0.5
LNSRCH,ON
PRED,ON   
NCNV,2
ALLS
SOLV
SAVE,KW-1,DB  
!*
!---------------------------- 循环做第二步到第五步的开挖，第一步到第四步的支护 ----------------------------!
!*
ALLS
ESEL,S,TYPE,,2
EKILL,ALL      
!----------------------------  第I步开挖,第I-1步支护 ---------------------!
*DIM,KWD_TOU,ARRAY,4
*DIM,KWD_WEI,ARRAY,4
*DIM,ZHD_TOU,ARRAY,4
*DIM,ZHD_WEI,ARRAY,4
KWD_TOU(1,1)=3,4,5,6
KWD_WEI(1,1)=2,3,4,5
ZHD_TOU(1,1)=2,3,4,5
ZHD_WEI(1,1)=1,2,3,4
*DO,I,1,4
        !*
        TOU=KWD_TOU(I,1)
        WEI=KWD_WEI(I,1)
        !*
        ALLS
        VSEL,S,,,CM_ZSDKW
        VSEL,A,,,CM_YSDKW
        VSEL,R,LOC,Z,DBKZDZ(WEI,1),DBKZDZ(TOU,1)
        ESLV,R            
        EKILL,ALL  
        !*
        !*
        TOU=ZHD_TOU(I,1)
        WEI=ZHD_WEI(I,1)
        !*
        ALLS
        VSEL,S,,,CM_ZDB                     
        VSEL,A,,,CM_YDB
        VSEL,R,LOC,Z,DBKZDZ(WEI,1),DBKZDZ(TOU,1)
        ESLV,R
        EALIVE,ALL      
        MPCHG,MAT_DB,ALL
        !*
        ALLS
        VSEL,S,,,CM_ZMG                     
        VSEL,A,,,CM_YMG
        VSEL,R,LOC,Z,DBKZDZ(WEI,1),DBKZDZ(TOU,1)
        ESLV,R
        MPCHG,MAT_MG,ALL
        !*
        ALLS
        ASEL,S,,,CM_ZGXW                     
        ASEL,A,,,CM_YGXW
        ASEL,R,LOC,Z,DBKZDZ(WEI,1),DBKZDZ(TOU,1)
        ESLA,R
        EALIVE,ALL        
        MPCHG,MAT_GXW,ALL
        !*
        ALLS
        ASEL,S,,,CM_ZGXW  
        ASEL,A,,,CM_YGXW
        ASEL,R,LOC,Z,DBKZDZ(WEI,1),DBKZDZ(TOU,1)
        ESLA,S
        SFE,ALL,,PRES,,ZH_MG
        ALLS
        !*
        TIME,I+2     
        NROPT,FULL
        AUTOTS,ON  
        DELTIM,0.3,0.001,0.5
        LNSRCH,ON  
        PRED,ON   
        NCNV,2
        !OUTRES,ALL,ALL
        ALLS
        SOLV
        SAVE,KW-%I+1%,DB  
        !*
*ENDDO
!-----------------------------------    第5步支护，这一步没有开挖     ----------------------------------!
TOU=6
WEI=5
!*
ALLS
VSEL,S,,,CM_ZDB                     
VSEL,A,,,CM_YDB
VSEL,R,LOC,Z,DBKZDZ(WEI,1),DBKZDZ(TOU,1)
ESLV,R
EALIVE,ALL      
MPCHG,MAT_DB,ALL
!*
ALLS
VSEL,S,,,CM_ZMG                     
VSEL,A,,,CM_YMG
VSEL,R,LOC,Z,DBKZDZ(WEI,1),DBKZDZ(TOU,1)
ESLV,R
MPCHG,MAT_MG,ALL
!*
ALLS
ASEL,S,,,CM_ZGXW                     
ASEL,A,,,CM_YGXW
ASEL,R,LOC,Z,DBKZDZ(WEI,1),DBKZDZ(TOU,1)
ESLA,R
EALIVE,ALL      
MPCHG,MAT_GXW,ALL
ALLS
ASEL,S,,,CM_ZGXW  
ASEL,A,,,CM_YGXW
ASEL,R,LOC,Z,DBKZDZ(WEI,1),DBKZDZ(TOU,1)
SFA,ALL,,PRES,ZH_MG
ALLS
!*
ALLS
TIME,7   
NROPT,FULL
AUTOTS,ON  
DELTIM,0.3,0.01,0.5
LNSRCH,ON  
PRED,ON   
!OUTRES,ALL,ALL
ALLS
SOLV
SAVE,KW-6,DB  
/EXIT,NOSAVE

zhangmeng

我最怕命令流了，不明不白的！简单介绍一下可以吗？

xsdcaifu

就是阿，没有说明很难看懂的

dongpeng14500

不错

crystally

是好东西

jiangfeng

好东西啊!

zhenxinghe

好东西

bjydly

不错，试一下先

追风

真是好东西啊

arcok

学习学习！好久都没振动了！

horizonzw

东西很不错，还请楼主把一些地方做些注视

shuoji007

楼主分享的很有借鉴的价值，顶