如何模拟裂纹

polaris008

最近在做关于路面结构的有限元分析，有几个问题想请教大家
1 多层沥青路面结构分别用什么单元类型比较好？
2 如何在路面上模拟裂纹？

欧阳中华

.
   我不是做道桥专业的，感觉多层沥青路面，如果是强度分析可以将各层用层合理论等效成一层，然后再分析，用块体单元，但应该考虑其粘性；模拟裂纹显然就不能如此简化，应该考虑各层的特性，而且是非线性问题.. ..

   这样的问题在相关的国内外刊物上应该有很多研究的文章吧，你查查看.. ..

polaris008

我也查了很多资料，主要是裂纹问题不能解决，没办法了。

欧阳中华

.
  你可以用“结构”、“裂纹”、“有限元”组合试试...

wsjxaut

用有限元分析裂纹，这本身就是件郁闷的事

AaronSpark

用ANSYS作裂纹走向预测的计算技巧

用ANSYS作裂纹走向预测的例子, 希望感兴趣的朋友多提宝贵意见.
! Looping Crack Propagation
/PMACRO
FINISH
/CLEAR,START ! Clear DB
/PREP7
! Set Parameters
*SET,PI,ACOS(-1)
*SET,MAXIT,3 ! Nmber of Iterations
*SET,CRACKINC,40 ! Crack Increment
*DIM,KPXY,ARRAY,100,2 ! Keypoint Array
! Geometery Keypoints
*SET,KPXY(1,1),0 $ *SET,KPXY(1,2),0
*SET,KPXY(2,1),5123 $ *SET,KPXY(2,2),0
*SET,KPXY(3,1),6805 $ *SET,KPXY(3,2),795
*SET,KPXY(4,1),7319 $ *SET,KPXY(4,2),2795
*SET,KPXY(5,1),6805 $ *SET,KPXY(5,2),2795
*SET,KPXY(6,1),6464 $ *SET,KPXY(6,2),1675
*SET,KPXY(7,1),5123 $ *SET,KPXY(7,2),1675
*SET,KPXY(8,1),5123 $
*SET,KPXY(9,1),0 $ *SET,KPXY(9,2),1675
*SET,KPXY(10,1),0 $ *SET,KPXY(10,2),290
*SET,KPXY(11,1),150 $ *SET,KPXY(11,2),290
*SET,MAXKP,11
!!!!!!!*DIM,NDIST,ARRAY,5,2
*DO,NUMIT,0,MAXIT
CSYS,0
/PREP7
ALLSEL,ALL ! Clear Geometery & Mesh
ACLEAR,ALL
ADELE,ALL, , ,1
*SET,KPXY(8,2),KPXY(MAXKP,2)
! Create Keypoints
*DO,J,1,MAXKP
K,J,KPXY(J,1),KPXY(J,2),0
*ENDDO

ALLSEL,ALL
! Create AREA 1 by Keypoints
A,2,3,4,5,6,7,8
ALLSEL,ALL
CM,LA1,LINE ! Area 1 lines
LSEL,NONE
! AREA 2
LSTR,7,9 $ LSTR,9,10
*DO,K,10,MAXKP-1
LSTR,K,K+1
*ENDDO
LSTR,8,MAXKP
KSLL,S
LSLK,S,1
AL,ALL
! AREA 3
KPSEL,S,KP,,10,MAXKP,1
LSLK,S,1
LGEN,2,ALL, , ,0,0,0, ,1
KPSEL,U,KP,,10,MAXKP,1
LSLK,S,1
CM,LTEMP,LINE
*SET,MAXKP2,KNEAR(MAXKP)
KSEL,S,KP,,MAXKP
KSEL,A,KP,,MAXKP2
NUMMRG,KP, , , ,LOW
CMSEL,S,LTEMP
KSLL,S
*SET,ENDKP,KNEAR(10)
KSEL,ALL
LSTR,ENDKP,1
LSTR,1,2
KSLL,S
KSEL,A,KP,,8
LSLK,S,1
AL,ALL
ALLSEL,ALL
! MESHING
ET,1,PLANE82 ! Set element type
KEYOPT,1,3,2 ! Plane strain (Z strain = 0.0) see HELP,PLANE82
KEYOPT,1,5,0 ! Basic element solution
KEYOPT,1,6,0 ! Basic element solution
MP,EX,1,32000
MP,NUXY,1,.25
KSCON,MAXKP,5,1,0,0.75,
TYPE,1
MAT,1
REAL,1
ESYS,0
SECNUM,
MSHAPE,0,2D
MSHKEY,0
AMESH,ALL
! LOADING & BOUNDERY CONDITIONS
KSEL,S,KP,,1
KSEL,A,KP,,ENDKP
KSEL,A,KP,,4,5,1
LSLK,S,1
DL,ALL, ,ALL,
KSEL,S,KP,,1,4,1
LSLK,S,1
SFL,ALL,PRES,.6,
ALLSEL,ALL
SBCTRAN ! Transfers solid model loads and boundary conditions to the FE model.
/PSF,PRES,NORM,2,0
! Create Path
! *** START OF PATH ***
!/PNUM,NODE,1
KSEL,S,KP,,MAXKP
NSLK,S
*GET,PNode1,NODE,0,NXTH
KSEL,S,KP,,MAXKP
LSLK,S
KSLL,S
KSEL,U,KP,,8,
LSLK,S,1
*GET,L1,LINE,0,NXTH
*GET,L2,LINE,L1,NXTH
LSEL,S,LINE,,L1
NSLL,S,1
*SET,PNode2,NNEAR(PNode1)
LSEL,S,LINE,,L1
NSLL,S,0
*SET,PNode3,NNEAR(PNode2)
LSEL,S,LINE,,L2
NSLL,S,1
*SET,PNode4,NNEAR(PNode1)
LSEL,S,LINE,,L2
NSLL,S,0
*SET,PNode5,NNEAR(PNode4)
ALLSEL,ALL
FINISH
/SOLU
SOLVE
FINISH
/POST1
! Set Active Coodintate System
*GET,ACSX,KP,MAXKP,LOC,X ! Active co-ordinate system X
*GET,ACSY,KP,MAXKP,LOC,Y ! Active co-ordinate system Y
*GET,ACSZ,KP,MAXKP,LOC,Z ! Active co-ordinate system Z
*GET,ACSX2,KP,MAXKP-1,LOC,X ! Active co-ordinate system X2
*GET,ACSY2,KP,MAXKP-1,LOC,Y ! Active co-ordinate system Y2
*GET,ACSZ2,KP,MAXKP-1,LOC,Z ! Active co-ordinate system Z2
*SET,ACSTHXY,ATAN2((ACSY-ACSY2),(ACSX-ACSX2))
LOCAL,11,0,ACSX,ACSY,ACSZ,(ACSTHXY*180/PI), , ,1,1,
CSYS,11
! Create Path
PATH,CRACKPTH,5,30,20,
PPATH,1,PNode1, , , ,11
PPATH,2,PNode2, , , ,11
PPATH,3,PNode3, , , ,11
PPATH,4,PNode4, , , ,11
PPATH,5,PNode5, , , ,11
CSYS, 11
KCALC,0,1,3,0
*GET,KI,KCALC,0,K,1
*GET,KII,KCALC,0,K,2
*GET,KIII,KCALC,0,K,3
*SET,MAXKP,MAXKP+1
*SET,THETAC,2*ATAN(1/(8*KI)*(2*KI+2*SQRT(KI**2+KII**2))) ! Crack angle
*SET,THETA,THETAC+ACSTHXY
*SET,KPXY(MAXKP,1),KPXY(MAXKP-1,1)+CRACKINC*COS(THETA)
*SET,KPXY(MAXKP,2),KPXY(MAXKP-1,2)+CRACKINC*SIN(THETA)
*ENDDO

来自iCAx网

xuruikl

沥青路面结构一般都是采用多层弹性/粘弹性体系进行研究
模拟发射裂纹之类的文章还是比较多的
可以找文章看看

polaris008

不太好找，能不能推荐几篇？