我碰到的超级奇怪的问题

zhugmnj

询问高手：我定义的mass单元的质量为0.485时，在计算时output窗口中显示的是0.16667；mass单元质量为100时，在计算时output窗口中显示的是33.333。为什么会相差3倍？？

glise

把你的单元设置说明一下

zhugmnj

mass单元的质量为0.485，在实常数设置项的y方向中输入了0.485。

kkkttt

试一下下面的代码运行是否正确

FINISH ! 退出以前模块
/CLEAR, NOSTART ! 清除数据,不加载初始化文件
!(1) 设置工程选项,求解选项,单元类型和实常数
/FILENAME, EX7.1 ! 定义工程文件名称
/PREP7 ! 加载前处理模块
/TITLE, EX7.1, NATURAL FREQUENCY OF A SPRING-MASS SYSTEM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND, PAGE 6, EX.1.2-2
ANTYPE,MODAL ! 定义分析类型为模态(MODAL)分析
MODOPT,REDUC,1,,,1 ! 显示所有模态
MXPAND,1 ! 展开第1阶频率
ET,1,COMBIN14,,,2 ! 定义第1类单元为2D纵向弹簧单元COMBIN14
ET,2,MASS21,,,4 ! 定义第2类单元为2D质量单元MASS21
R,1, 8406.4 ! 定义第1类实常数,弹簧刚度系数k=8406.4 N/m
R,2, 11.121/9.8 ! 定义第2类实常数,集中质量m=11.121/9.8 kg
!(2) 定义模型节点和单元连接关系
N , 1 ! 在坐标原点(0,0,0)定义第1号结点
N,2,,1 ! 在坐标(0,1,0)定义第2号结点
E,1,2 ! 过1号节点和2号节点定义单元
TYPE,2 ! 将默认的单元类型从弹簧单元,改变为第2类单元(质量单元)
REAL,2 ! 将默认的实常数从弹簧刚度,改变为第2类实常数(集中质量)
E , 2 ! 用第2个节点定义第2个单元
M,2,UY ! 指定2号节点的Uy自由度为主自由度
ANSYS分析实例与工程应用
302
!(3) 指定输出选项,位移约束
OUTPR,ALL,1 ! 输出第1阶频率的所有内容
OUTRES,ALL,0 ! 所有数据不记录到数据库
D,1,ALL ! 约束1号节点的所有位移自由度
D,2,UX ! 约束2号节点的X方向自由度UX
FINISH ! 退出前处理模块PREP7
!(4) 进入求解模块求解
/SOLU ! 加载求解模块
SOLVE ! 开始求解
!(5) 提取计算结果
*GET,FREQ,MODE,1,FREQ ! 提取第1阶模态的频率计算结果,存入变量FREQ
!(6) 定义数组变量,将计算结果输出到文本文件
*DIM,LABEL,CHAR,1,2 ! 定义1*2的字符型变量LABEL
*DIM,VALUE,,1,3 ! 定义默认为数值型的1*3的数值型变量VALUE
LABEL(1,1) = ' F,' ! 给数组元素LABEL(1,1)变量赋值字符串
LABEL(1,2) = '(Hz) ' ! 给数组元素LABEL(1,2)变量赋值字符串
*VFILL,VALUE(1,1),DATA,13.701 ! 给数组元素LABEL(1,1)变量赋理论值13.701
*VFILL,VALUE(1,2),DATA,FREQ ! 给数组元素LABEL(1,2)变量赋计算值FREQ
*VFILL,VALUE(1,3),DATA,ABS(FREQ/13.701) ! 给数组元素LABEL(1,3)变量赋频率计算结
果和理论值的比值
/COM
/OUT, EX7_1, out ! 将输出内容重定向到文件EX7_1.out
/COM,------------------- EX7.1 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT ! 结束数据重定向,关闭输出文件
FINISH ! 退出求解模块SOLU
*LIST, EX7_1, out ! 列表显示结果文件EX7_1.out的内容