关于转子轴承系统模型问题

Agoni · 发表于 2015-10-17 12:14

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？我要加入

x

对转子轴承系统进行分析，轴承是滚动轴承
这里轴承和转子的关系应该怎么建立？
是用接触对吗？如果是接触对那应该如何实现？

Chelsea · 发表于 2015-10-19 18:42

ANSYS APDL命令和轴承接触分析相关实例。

　　finish
　　/clear
　　/filename,ex5-3 !设定工作名
　　/title,the contact analysis of Bearing !设定工作标题
　　!************************************
　　!进入前处理模块
　　!************************************
　　/prep7
　　*set,roll_r,5.7 !定义变量参数
　　*set,inside_r1,15
　　*set,inside_r2,18.5
　　*set,outside_r1,29.8
　　*set,outside_r2,33.3
　　*set,deep,8
　　*set,axes_r3,15.5
　　*set,fillet_r4,1
　　*set,axes_deep,20
　　*set,fillet_r5,1
　　!定义单元类型和属性
　　et,1,solid45 !定义单元类型solid45
　　MP,EX,1,2.06e5 !定义弹性模量
　　MP,PRXY,1,0.3 !定义泊松比
　　MP,MU,1,0.3 !定义摩擦系数
　　!建立模型
　　sph4,,-inside_r2-roll_r,roll_r+0.9 !生成轴承滚珠
　　cyl4,,,inside_r1,-120,inside_r2,-60,deep !生成+z向的轴承内圈
　　cyl4,,,outside_r1,-120,outside_r2,-60,deep !生成+z向的轴承外圈
　　cyl4,,,inside_r1,-120,inside_r2,-60,-deep !生成-z向的轴承内圈
　　cyl4,,,outside_r1,-120,outside_r2,-60,-deep !生成-z向的轴承外圈
　　wpoff,0,0,-deep !偏移工作平面
　　cyl4,,,0,-120,axes_r3,-60,-axes_deep !生成装配轴
　　lfillt,57,59,fillet_r4,, !生成倒角线
　　al,57,62,59,54,61 !由线生成面
　　vrotat,32,,,,,,42,37,60,1, !旋转面生成体
　　vdele,6,,,1 !删除编号为6的体
　　!
　　lfillt,31,39,fillet_r5,, !生成倒角线
　　al,34,39,53,31,37 !由线生成面
　　vdrag,27,,,,,,35 !拖拉面生成体
　　vdele,4,,,1 !删除编号为4的体
　　!
　　vgen,,7,,,,,0.27,,,1 !平移编号为7的体
　　!
　　wpoff,0,0,deep !偏移工作平面
　　csys,1 !激活柱坐标系
　　asel,s,loc,x,inside_r2 !选择x=inside_r2的面
　　asel,a,loc,x,outside_r1 !选择x=ouside_r1的面
　　vsba,1,all !体被面分割
　　vdele,4,,,1 !删除编号为4的体
　　vdele,8,,,1 !删除编号为8的体
　　allsel,all !选择全部图元
　　vsel,u,volu,,7 !不选编号为7的体
　　vglue,all !粘接全部的体
　　!以下通过一些布尔操作以方便网格划分
　　wpoff,0,-inside_r2-roll_r,0 !偏移工作平面
　　vsbw,1 !用工作平面分割体1
　　wpro,,-90, !旋转工作平面
　　vsbw,2 !用工作平面分割体2
　　vsbw,3 !用工作平面分割体3
　　wpro,,,-90 !旋转工作平面
　　vsbw,1 !用工作平面分割体1
　　vsbw,2 !用工作平面分割体2
　　vsbw,5 !用工作平面分割体5
　　vsbw,6 !用工作平面分割体6
　　!
　　voffst,2,-4 !沿面的法向平移面2生成体
　　voffst,9,-4 !沿面的法向平移面9生成体
　　voffst,23,-4 !沿面的法向平移面23生成体
　　voffst,53,-4 !沿面的法向平移面53生成体
　　!
　　voffst,3,4 !沿面的法向平移面3生成体
　　voffst,25,4 !沿面的法向平移面25生成体
　　voffst,38,4 !沿面的法向平移面38生成体
　　voffst,58,4 !沿面的法向平移面58生成体
　　!
　　vovlap,all !对体进行搭接操作
　　vdele,25,,,1 !删除编号为25的体及其所属的低阶图元
　　vdele,32,,,1 !删除编号为32的体及其所属的低阶图元
　　vdele,33,,,1 !删除编号为33的体及其所属的低阶图元
　　vdele,34,,,1 !删除编号为34的体及其所属的低阶图元
　　!
　　vdele,31,,,1 !删除编号为31的体及其所属的低阶图元
　　vdele,35,,,1 !删除编号为35的体及其所属的低阶图元
　　vdele,36,,,1 !删除编号为36的体及其所属的低阶图元
　　vdele,37,,,1 !删除编号为37的体及其所属的低阶图元
　　vglue,all !对体进行粘接操作
　　!划分网格
　　esize,2 !设定网格单元尺寸
　　mshape,0,3d !设定网格形状为六面体单元
　　mshkey,1 !设定为映射网格划分方式
　　vsel,s,volu,,1,3,2 !选择编号为1、3 的体
　　vsel,a,volu,,4,5 !同时选择编号为4,5的体
　　vsel,a,volu,,9 !同时选择编号为9的体
　　vsel,a,volu,,12,14 !同时选择编号为12、13、14的体
　　cm,sphere,volu !生成体的组件sphere
　　vmesh,all !对体进行网格划分
　　!
　　esize,1 !设定网格单元尺寸
　　!vsel,inve,volu !对当前体选择集进行反选
　　vsel,s,volu,,6
　　vsel,a,volu,,22,23
　　vsel,a,volu,,26,30
　　vsel,a,volu,,38,40
　　vsweep,all !对体sweep网格划分
　　esize,1.5 !设定网格单元尺寸
　　allsel,all
　　vsweep,8,50,49 !设定源面和目标面并进行sweep网格划分
　　vsweep,7,32,37 !设定源面和目标面并进行sweep网格划分
　　!
　　!生成耦合设置
　　cmsel,s,sphere,volu !选择名称为sphere的组件
　　vgen,2,all,,,,,,,0 !复制该组件
　　cmsel,s,sphere,volu !选择名称为sphere的组件
　　vclear,all !清除该组件包含图元的网格
　　vdele,all,,,1 !删除该组件包含的图元
　　!
　　csys,1 !激活柱坐标系
　　asel,s,loc,x,inside_r2 !选择x=inside_r2的面
　　asel,a,loc,x,outside_r1 !同时选中x=outside_r1的面
　　asel,u,loc,y,-90 !从当前选择集中不选y=-90的面
　　nsla,s,1 !选择面所属的节点
　　nrotat,all !旋转节点坐标系与当前激活坐标系平齐
　　cpintf,ux !在重合节点生成自由度ux的耦合设置
　　cpintf,uy !在重合节点生成自由度uy的耦合设置
　　cpintf,uz !在重合节点生成自由度uz的耦合设置
　　!
　　!设定接触参数
　　/PREP7
　　ALLSEL,ALL !选择全部图元
　　/COM, CONTACT PAIR CREATION - START !接触对设置开始
　　/GSAV,cwz,gsav,,temp !将当前的图形设置保存在cwz.gsav文件中
　　!
　　MP,MU,1,0.3 !定义摩擦系数
　　MAT,1 !激活材料属性1
　　R,3 !定义实常数3
　　REAL,3 !激活实常数3
　　ET,2,170 !定义单元类型2
　　ET,3,174 !定义单元类型3
　　KEYOPT,3,9,0 !设定单元类型3的关键项9
　　KEYOPT,3,10,1 !设定单元类型3的关键向10
　　R,3,,,0.1, !设定法向接触刚度为0.1
　　!生成目标面
　　ASEL,S,,,30 !选择编号为30的面
　　ASEL,A,,,90 !同时选中编号为90的面
　　ASEL,A,,,98 !同时选中编号为98的面
　　ASEL,A,,,104 !同时选中编号为104的面
　　ASEL,A,,,113 !同时选中编号为113的面
　　ASEL,A,,,138 !同时选中编号为138的面
　　ASEL,A,,,143 !同时选中编号为143的面
　　CM,AREA_TARGET,AREA !生成目标面组件target
　　TYPE,2 !激活单元类型2
　　NSLA,S,1 !选择面所属的节点
　　ESLN,S,0 !选择节点依附的单元
　　ESURF !在当前选择的单元上覆盖生成单元
　　ESEL,ALL !选择所有的单元
　　!生成接触面
　　ASEL,S,,,35 !选择编号为35的面
　　ASEL,A,,,36 !同时选中编号为36的面
　　CM,AREA_CONTACT,AREA !生成接触面组件contact
　　TYPE,3 !激活单元类型3
　　NSLA,S,1 !选择面所属的节点
　　ESLN,S,0 !选择节点依附的单元
　　ESURF !在当前选择的单元上覆盖生成单元
　　ALLSEL !选择全部图元
　　ESEL,ALL !选择全部单元
　　ESEL,S,TYPE,,2 !选择单元类型为2的单元
　　ESEL,A,TYPE,,3 !同时选中单元类型为3的单元
　　ESEL,R,REAL,,3 !在当前选择集中选出实常数为3的单元
　　/PSYMB,ESYS,1 !打开单元坐标系显示
　　/PNUM,TYPE,1 !打开单元类型编号
　　/NUM,1 !打开颜色显示
　　EPLOT !图形显示单元
　　ALLSEL,ALL !选择全部图元
　　/GRES,cwz,gsav !从cwz.gsav文件中恢复图形设置
　　/COM, CONTACT PAIR CREATION - END !接触对结束
　　!**********************************
　　!进入求解模块
　　!**********************************
　　/solu !进入求解模块
　　csys,1 !激活柱坐标系
　　nsel,s,loc,x,outside_r2 !选择x=outside_r2的节点
　　d,all,all !在节点上施加全部自由度约束
　　asel,s,loc,y,-60 !选择y=-60的面
　　asel,a,loc,y,-120 !同时选中y=-120的面
　　da,all,symm !施加对称边界条件
　　!施加装配轴的移动位移
　　da,33,uz,2*deep !在编号为33的面上施加位移约束
　　!非线性求解设置
　　lnsrch,on !打开线性搜索
　　pred,on !打开预测矫正
　　autot,on !打开自动时间步
　　nsubst,40,100,10 !设定子步数
　　outres,all,all !输出所有子步上的全部数据
　　allsel,all !选择所有图元
　　solve !开始求解
　　!**********************************
　　!进入后处理模块
　　!**********************************
　　/POST1 !进入通用后处理器
　　PLDISP,2 !图形显示结构变形图
　　/DSCALE,1,1.0 !设定显示比例为1.0
　　/EXPAND,6,POLAR,FULL,0,60,0,, !将结果扩展到360度
　　/REPLOT !重绘当前图形
　　PLNSOL,S,Z !图形显示z方向的应力
　　PLNSOL,S,EQV !图形显示平均等效应力
　　PLNSOL, CONT,PRES, 0,1.0 !接触应力等值线图
　　PLNSOL, CONT,STAT, 0,1.0 !接触状态等值线图
　　PLDI,2,
　　ANMODE,10,0.5, ,0 !变形前后动画效果
　　FINISH !后处理模块结束
　　/EXIT,ALL !退出并保存全部数据

复制代码

Agoni · 发表于 2015-10-28 07:12

Chelsea 发表于 2015-10-19 18:42
ANSYS APDL命令和轴承接触分析相关实例。

谢谢，先仔细学习一下

fzl529 · 发表于 2016-4-25 15:59

请问这个范例是那本书给出的？

Chelsea · 发表于 2016-4-25 16:53

fzl529 发表于 2016-4-25 15:59
请问这个范例是那本书给出的？

这个确实应该是某本书的配套光盘中流传出来的资料，应该是好多年前的一本书了，具体那本书，本人无法考证

fzl529 · 发表于 2016-4-25 18:24

Chelsea 发表于 2016-4-25 16:53
这个确实应该是某本书的配套光盘中流传出来的资料，应该是好多年前的一本书了，具体那本书，本人无法考证

嗯。
直接拷贝运行，后处理中有问题。
很多年前查文献，看到天大有一个老师的几届硕士都做类似的工作，后来没有继续关注了。
这个模型没有考虑沟道曲率。
实际当中由沟道与球形成的所谓密合度问题，影响了经典赫兹解在球轴承中的应用。
学习了，谢谢。有时间再仔细看看。

zghitboy · 发表于 2016-4-26 13:54

滚动轴承动特性及轴承—转子系统动力学模型研究吴昊
【摘要】：滚动轴承支承的转子系统广泛应用于工业领域,滚动轴承的动特性在很大程度上决定着轴承-转子系统的动力学性能。对于滚动轴承支承的转子系统动力学性能研究的关键是如何精确计算滚动轴承的刚度和阻尼的数值、弄清轴承结构刚度及其对转子系统刚度的影响。以往的研究在计算滚动轴承的刚度和阻尼时,没有同时考虑轴承变形和油膜的影响,在进行转子振动模型研究中,将滚动轴承简化为具有径向刚度和阻尼的一个点。这样的做法使得目前对实际滚动轴承-转子系统的振动问题的研究精度不高,难以进行有效的理论分析和计算。本文分别以球轴承、圆柱滚子轴承和圆锥滚子轴承为对象,首次提出了综合刚度概念和计算思想,通过受力分析和EHL研究,建立了考虑润滑油膜、内外圈弹性变形和滚动体弹性变形的滚动轴承综合刚度的解析计算模型,并详细研究了滚动轴承的滚子长度、滚子直径、滚子个数、径向载荷、转动速度等因素对轴承综合刚度的影响规律,并对这些规律进行了分析和讨论；首次提出了综合阻尼的概念和计算思想。通过对球轴承、圆锥滚子轴承和圆柱滚子轴承的受力和变形分析,以及对Reynolds方程进行二次积分,建立了球轴承、圆锥滚子轴承和圆柱滚子轴承的综合阻尼的计算模型。依据该模型分别研究了圆柱滚子、圆锥滚子和球轴承的结构参数对轴承综合阻尼的影响规律,并对这些影响规律进行了理论分析。以滚动轴承支承的Jeffcott转子和链式悬臂转子系统为研究对象,利用新建立的滚动轴承综合刚度和综合阻尼模型进行动力学分析,系统研究了滚动轴承结构参数(滚子长度、滚子半径等)和工作状态参数(转速、外载荷)对于转子系统临界转速和转子系统不平衡响应的影响规律,研究了圆柱滚子轴承的滚子长度、悬臂长度、轴承间距等结构参数对链式悬臂转子的临界转速、振动响应等振动性能的影响规律,并进行了分析讨论。通过对圆柱滚子轴承、圆锥滚子轴承、球轴承的结构力学分析,建立了滚动轴承的结构刚度计算模型,将滚动轴承结构刚度计算模型引入转子振动分析过程,建立了滚动轴承单元两端的新型传递关系,并将此传递关系引入整个轴承-转子系统的传递矩阵中,建立了考虑轴承具体结构的新型传递矩阵；依据新建立的传递矩阵构建了滚动轴承-转子系统的振动计算模型,并对一实际轴承-转子系统进行了计算研究,系统分析了滚动轴承结构参数对轴承-转子系统的模态振型、临界转速和不平衡响应的影响规律。研究表明,滚动轴承(尤其是圆柱滚子轴承和圆锥滚子轴承)的几何结构对转子系统的模态振型有较大的影响,尤其是对于靠近轴承两端的模态振型有明显的影响,对转子系统不平衡响应的临界转速影响不大,对不平衡响应的振幅有一定程度的抑制作用,其中圆柱滚子轴承对响应振幅的抑制十分明显。将本文建立的新型滚子轴承刚度模型、阻尼模型、轴承结构刚度模型以及新型转子传递矩阵模型应用于某一核电站风机转子的振动分析,计算得到了风机系统的模态振型、临界转速以及风机叶轮中心处的不平衡响应曲线,分析了轴承结构对该风机转子系统的振动性能的影响规律。并利用有限元法对同一算例进行分析计算,计算结果表明,用有限元法计算的结果与应用本文所建立的刚度模型、阻尼模型、轴承结构刚度模型所计算的结果具有良好的一致性,表明本文所建立的刚度模型、阻尼模型、轴承结构模型、对传递矩阵的修改具有良好的工程应用的可行性和可信性。通过本文的研究,构建了关于滚动轴承刚度、阻尼的新型计算模型,构建了关于轴承结构刚度的计算模型和新型传递矩阵计算模型,这些模型不仅在计算精度上有了很大的提高,而且计算过程十分方便。本文的研究成果将为滚动轴承支承的转子系统动力学性能研究提供有益的借鉴。
【关键词】：滚动轴承刚度阻尼转子结构刚度传递矩阵动特性

账号		自动登录	找回密码
密码			我要加入

[结构分析] 关于转子轴承系统模型问题

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

本帖被以下淘专辑推荐:

相关帖子

点评