一个 ANSYS地震分析算例

shenliying

ANSYS地震分析算例


! 一个四层弹簧－质点模型的地震ANSYS分析
! Example of seismic analysis in ANSYS
! 包括频率分析，谱分析和时程分析
! With model & frequency analysis, spectrum analysis and transient analysis
! 作者：陆新征，清华大学土木工程系
! Author: Lu Xinzheng Dept. Civil Engrg. of Tsinghua University

[Money=20]


FINI
/CLEAR
/UNITS,SI
/PREP7
DAMPRATIO=0.02 !振型阻尼系数都为0.02
ET,1,BEAM188
KEYOPT,1,7,1
KEYOPT,1,8,1
ET,2,MASS21,,,4
MP,EX,1,210E9
MP,NUXY,1,0.3
MP,DENS,1,7800
MPDATA,DAMP,1,,DAMPRATIO
SECTYPE,3,BEAM,I
SECDATA,0.2,0.2,0.5,0.01,0.01,0.008
R,1,1.6E2,1.6E2
R,2,1.2E2,1.2E2
K,1,0,0,0
K,2,0,3,0
K,3,0,6,0
K,4,0,9,0
K,5,0,12,0
K,6,0,0,10000
L,1,2
L,2,3
L,3,4
L,4,5
LSEL,,,,1,4
LATT,1,0,1,,6,,3
ALLS
LESIZE,ALL, , ,3 , , , , ,1
LMESH,ALL
NUMMRG,ALL
NUMCMP,ALL
TYPE,2
REAL,1
E,2
TYPE,2
REAL,2
E,8
E,14
E,20
*SET,NT,1001
*SET,DT,0.02
*DIM,AC,,NT
*VREAD,AC(1),RECORD,TXT
(F8.3)
/SOLU
D,1,ALL,
ANTYPE,0
SOLVE
FINISH
/SOLU !模态分析
ANTYPE,2
MODOPT,SUBSP,8
MXPAND,8, , ,1
SOLVE
FINI
!得到自振频率1
*GET,FREQ1,MODE,1,FREQ
/ESHAPE,1.0
/SOLU
ANTYPE,SPECTR !谱分析
SPOPT,SPRS
MDAMP,1,DAMPRATIO, , , , , ,
SED,1
SVTYPE,2,1
FREQ,0.167,0.25,0.333,0.44444,0.5,0.667,1,1.25,1.667
SV,,0.154350625,0.191590625,0.210210625,0.224175625,0.250716714,0.329514922,0.484352764,0.598723486,0.786897371
FREQ,2.222,10,100000
SV,,1.034212766,1.034212766,0.3528
!按7度多遇地震，地震影响系数0.08 第一组III场地TG＝0.45
SRSS,0.01,DISP
SOLVE
FINISH
/POST1
/INP,,MCOM
NSORT,U,SUM
*GET,DMAX_SPE,SORT, ,MAX !反应谱最大变形
!开始地震计算
FINISH
/CONFIG,NRES,20000
/SOLU
ANTYPE,TRANS
TRNOPT,FULL
ALPHAD,2*DAMPRATIO*FREQ1*2*3.1415926
BETAD,2*DAMPRATIO/(FREQ1*2*3.1415926)
*DO,I,1,1001
ACEL,AC(I),0,0
TIME,I*0.02
OUTRES,ALL,ALL
SOLVE
*ENDDO
FINISH
/POST26
FILE
NSOL,2,20,U,X,
PLVAR,2, , , , , , , , , ,
STORE,MERGE
XVAR,1
PLVAR,2,
*GET,DMAX_TRANS,VARI,2,EXTREM,VMAX, , ! 时程分析最大位移



地震数据需要做成数据文件放在相应的工作目录下面。

xuruikl

陆新征老师的个人主页有很多很好的东西
推荐有兴趣的朋友看看

whyingpost

请问陆新征老师的个人主页链接是什么？呀
多谢

[ 本帖最后由 rodge 于 2008-3-24 03:56 编辑 ]

shenliying

可以直接搜吧

xuruikl

http://www.luxinzheng.net/

NIYA

需要中:victory:

shenliying

ALPHAD,2*DAMPRATIO*FREQ1*2*3.1415926
BETAD,2*DAMPRATIO/(FREQ1*2*3.1415926)
  是用来确定结构阻尼的么？

shenliying

ansys 里面有多种阻尼的输入方式 动力学分析选用那种最好呢

rodge

ansys中的阻尼有多种输入方式，但问题是，针对不同的问题，并不是几种输入都有效的，对于动力学分析这块，常见的就是输入ALPHAD值和BETAD值

shenliying

那您知道ALPHAD值和BETAD值是怎么确定的呢，感觉结构的阻尼比较难确定呢，书上有例子是取0.05和0.01的不知道这些数据是从何而来呢

egotrip

感觉做的不错,但是有些疑问,楼主的计算顺序是:静力分析-->模态分析-->单点谱分析-->瞬态分析,谱分析和最后的瞬态分析好像没有什么必然联系吧,如果想得到瞬态解,不需要做谱分析吧?还有第一步的静力分析,如果模态分析没有打开预应力选项,为什么第一步要做静力分析呢?希望楼主能指点一下,谢谢

shenliying

这个例子是从陆新征老师那里转来的

shenliying

再向请问各位大虾 哪里能查到材料的阻尼系数呢

mq1986

我觉得楼主引用的帖子在设置瑞利阻尼方面有些疑问，所以想探讨下

命令 ALPHAD 和 BETAD 分别用于确定瑞利（Rayleigh）阻尼常数α和β。通常α和β的值不是直接得到的，而是用振型阻尼比  计算出来的。  是某个振型i的实际阻尼和临界阻尼之比。如果  是模态i的固有角频率，则α和β满足下列关系：
α / (2 * ω) + β * ω / 2 = ξ
在许多实际问题中，Alpha阻尼（或称质量阻尼）可以忽略（α=0）。这种情形下，可以由已知的  和  计算出β=2*DAMPRATIO/(FREQ1*2*3.1415926)

同理，在忽略β的前提下， α =2*DAMPRATIO*FREQ1*2*3.1415926

所以，在同时考虑α 、 β时，假如还用 α =2*DAMPRATIO*FREQ1*2*3.1415926
β=2*DAMPRATIO/(FREQ1*2*3.1415926)，应该有问题吧？

中南之沙

这个算例看到很多次了