ansys热分析实例整理

NASA

Emp1:

1. 
   
2. /GRA,POWER
   
3. /NOPR                           ! set preferences for menu filtering to thermal
   
4. /PMETH,OFF  
   
5. KEYW,PR_SET,1    !KEYW, Keyword, KEY — Sets a keyword used by the GUI for context filtering
   
6. KEYW,PR_THERM,1
   
7. /GO               !/GO — Reactivates suppressed printout
   
8. /COM,   
   
9. /COM,Preferences for GUI filtering have been set to display:
   
10. /COM,  Thermal  !/COM, Comment — Places a comment in the output
    
11. /FILNAM,wkshop1         ! set jobname to "wkshop1"
    
12. /TITLE,Workshop 1 - Basic Heat Transfer Analysis of a Fin   
    
13. /PREP7                        ! enter the preprocessor  
    
14. ET,1,PLANE55                ! define element type 3, PLANE55
    
15. MP,KXX,1,10,                ! define material properties only KXX is required  
    
16. RECTNG,0.0,0.6,0.0,0.1, ! create fin geometry using rectangle command
    
17. LSEL,S,LOC,X,0        ! select line by location x = 0
    
18. LESIZE,ALL,,,1                ! set number of division on all selected  lines to 1
    
19. ALLSEL,ALL                ! select everything
    
20. LSEL,S,LOC,Y,0.1        ! select line by location, y = 0.1
    
21. LESIZE,ALL,,,12        ! set number of divisions on all selected lines to 12
    
22. ALLSEL,ALL                ! select everythinghelp,amesh
    
23. LPLOT                           ! plot lines
    
24. MSHAPE,0,2D                ! specify mapped meshing
    
25. MSHKEY,1
    
26. AMESH,ALL                ! mesh all areas
    
27. FINISH                        ! exit the preprocessor  
    
28. /SOLU                           ! enter solution
    
29. LSEL,S,LOC,X,0        ! select line at base on fin for temp loading
    
30. DL,ALL,,TEMP,300        ! set temperature on line to 300
    
31. ALLSEL,ALL                ! select everything
    
32. LSEL,S,LOC,Y,0        ! select lower line for convection loading
    
33. LSEL,A,LOC,Y,0.1        ! select top line for convection loadingsave
    
34. SFL,ALL,CONV,0.4, ,80,        ! apply convection to lines, top and bottom
    
35. ALLSEL,ALL                ! select everything
    
36. SAVE                        ! save the databse before solution
    
37. /STAT,SOLU                  ! review status before solution
    
38. SOLVE                        ! execute solution   
    
39. FINISH                          ! exit solution
    
40. /POST1                          ! begin postprocessing
    
41. PLNSOL,TEMP, ,0,        ! plot nodal solution, temperature
    
42. PATH,path1,2,30,20,                ! name a path, path1 !Defines a path name and establishes parameters for the path.
    
43. PPATH,1,,0,0.1        ! define the coordinates of the first point on the path
    
44. PPATH,2,,0.6,0.1        ! define the coordinates of the second point on the path
    
45. PDEF,STAT        ! review path definition   
    
46. PDEF,tupper,TEMP, ,AVG                ! map data onto path  
    
47. PLPATH,TUPPER                        ! produce a path plot   
    
48. PRPATH,TUPPER                        ! list path items
    
49. PLPAGM,TUPPER,1,'NODE'          ! produce a path plot on geometry       
    
50. PLNSOL,TF,X,0,                  ! produce plot of thermal flux in x-dir
    
51. /VSCALE,1,1,0              !PLPAGM, Item, Gscale, Nopt — Displays path items along the path geometry
    
52. PLVECT,TF, , , ,VECT,NODE,ON,0        ! produce a vector plot of flux  
    
53. PRRSOL,HEAT                         ! list reaction solution, heat
    
54. qactual = 96.526                         ! define scalar parameters
    
55. qideal = 0.4*2.0*0.6*(300-80)          ! calculate q ideal
    
56. eta = qactual/qideal                    ! define/calculate fin efficiency
    
57. SAVE                ! PLVECT, Item, Lab2, Lab3, LabP, Mode, Loc, Edge — Displays results as vectors

复制代码

[ 本帖最后由 yejet 于 2006-11-13 09:10 编辑 ]

yejet

Emp2

1. /SHO,plots,grph
   
2. /AUTO      !/AUTO, WN — Resets the focus and distance specifications to "automatically calculated
   
3. /GRAP,FULL
   
4. /TYP,,4    $/COM,
   
5. /COM, Preferences for GUI filtering have been set to display:
   
6. /COM,  Thermal     $KEYW,PR_SET,1   
   
7. !KEYW, Keyword, KEY — Sets a keyword used by the GUI for
   
8. !context filtering
   
9. KEYW,PR_THERM,1    $/FILNAM,wkshop2
   
10. /TITLE,Workshop #2 - Full Power Transistor Analysis - Steady-State  
    
11. /PREP7                 !*  Define Geometry
    
12. RECTNG,,.01,0.03+0.01+.0025,0.03+0.01+.0025+0.0075
    
13. RECTNG,,.0225,0.03+0.01,0.03+0.01+.0025
    
14. RECTNG,,.0225,0.03,0.03+0.01
    
15. RECTNG,,.0025,,0.03
    
16. RECTNG,.0075,0.0125,,0.03
    
17. RECTNG,.0175,.0225,,0.03
    
18. AGLU,ALL
    
19. LFILLT,14,33,.0025, ,
    
20. LFILLT,33,20,0.0025, ,
    
21. LFILLT,18,34,0.0025, ,
    
22. LFILLT,34,24,0.0025, ,
    
23. AL,7,8,9
    
24. AL,10,11,33
    
25. AL,12,15,16
    
26. AL,22,23,34
    
27. ASEL,,LOC,Y,0,0.04  $AADD,ALL   
    
28. ! KEYOPT, ITYPE, KNUM, VALUE — Sets element key options
    
29. ET,1,PLANE77                           ! 2-D 8 node thermal solid elem
    
30. KEYOPT,1,1,0                           ! Consistent C matrix
    
31. KEYOPT,1,3,0                           ! Planar
    
32. ET,2,SURF151                           ! Thermal surface effect elem
    
33. KEYOPT,2,3,0                           ! Planar
    
34. KEYOPT,2,4,0                           ! Include midside node
    
35. KEYOPT,2,5,1                           ! Extra node for convection
    
36. KEYOPT,2,6,0                           ! Extra node is fluid temp
    
37. KEYOPT,2,8,2                           ! Evaluate Hf at average temp
    
38. KEYOPT,2,9,0                           ! Exclude radiation
    
39. R,1                                      ! real set 1
    
40. R,2                                      ! real set 2
    
41. UIMP,1,DENS, , ,3500,                ! density for material 1
    
42. UIMP,1,KXX, , ,50,                    ! thermal conductivity for material 1
    
43. UIMP,1,C, , ,500,                    ! specific heat for material 1
    
44. UIMP,2,DENS, , ,8900,                ! material 2 properties
    
45. UIMP,2,KXX, , ,393,         !UIMP, MAT, Lab1, Lab2, Lab3, VAL1, VAL2, VAL3
    
46. UIMP,2,C, , ,385,         !Defines constant material properties (GUI)
    
47. UIMP,3,DENS, , ,2700,                ! material 3 properties
    
48. UIMP,3,KXX, , ,156,
    
49. UIMP,3,C, , ,963,
    
50. ASEL,,LOC,Y,0.0425,0.05                ! assign attributes to area 1
    
51. AATT,1,1,1
    
52. ASEL,,LOC,Y,0.04,0.0425                ! assign attributes to area 2
    
53. AATT,2,1,1
    
54. ASEL,,LOC,Y,0,0.04                ! assign attributes to area 3
    
55. AATT,3,1,1
    
56. SMRT,3                                ! set smart size level 3
    
57. ALLSEL                                ! select everything
    
58. AMES,ALL                        ! mesh all areas
    
59. LSEL,R,EXT                        ! select external lines
    
60. LSEL,R,LOC,X,.001,1                ! reselect lines by location
    
61. LSEL,R,LOC,Y,-1,.042
    
62. NSLL,,1                            ! select nodes attached to lines
    
63. ESLN                          ! select elements attached to selected nodes
    
64. N,5000,,-0.01                   ! define node 5000
    
65. TYPE,2        $ REAL,2         ! set meshing attributes to type 2, real 2
    
66. !ESURF — Generates elements overlaid on the free faces of existing selected elements.
    
67. ESURF,5000                        ! create surf151 elem, extra node is 5000
    
68. ALLSEL                                ! select everything
    
69. SAVE,transistor,db                ! save the database as transistor.db
    
70. SAVE                                ! save the database as jobname.db
    
71. /SOLUTION         !BFA, AREA, Lab, VAL1, VAL2, VAL3, PHASE — Defines a body force load on an area.
    
72. BFA,1,HGEN,5333334        ! Apply heat generation to transistor
    
73. SFL,2,HFLUX,1500                ! Apply heat flux to lines
    
74. SFL,30,HFLUX,1500                ! Apply heat flux to lines
    
75. SFL,3,HFLUX,1500       
    
76. ESEL,,TYPE,,2                    ! Select surf. Effect elements
    
77. SFE,ALL,1,CONV,,51     ! Apply  Conv. to Surf. Eff. Elem.
    
78. ALLSEL
    
79. D,5000,TEMP,50                   ! Extra node fixed at ambient temp
    
80. /PBC,TEMP,1             !!*  Visually verify loads
    
81. /PBF,HGEN,,1            !/PSF, Item, Comp, KEY, KSHELL — Shows surface load symbols on model displays
    
82. /PSF,CONV,2   $EPLO
    
83. SAVE  $SOLVE  $FINISH   $/POST1                       
    
84. ESEL,S,TYPE,,1                  ! select all type 1 ,PLANE77 elements
    
85. ALLSEL,BELOW,ELEM  
    
86. ! select everything below the selected elements
    
87. NSLE,S                          ! select nodes attached to elements
    
88. PLNSOL,TEMP, ,0,                ! plot nodal solution, temperature
    
89. NSORT,TEMP, ,0,0,_Z3,0          ! sort nodes based on temperature
    
90. PRNSOL,TEMP,                        ! print sorted list
    
91. NUSORT                          ! unsort nodes
    
92. /ZOOM,1,RECT,-0.554972,0.504832,0.183702,0.968805   
    
93. ! zoom up on hot areas
    
94. /GRAPHICS,FULL                  ! turn power graphics off
    
95. ALLSEL,ALL                          ! select everything
    
96. PRRSOL,HEAT                 ! print reaction solution, heat flow rate
    
97. NSEL,S,TEMP,,100,106, ,0        ! select nodes by results, temperature
    
98. NPLOT                           ! plot nodes for checking
    
99. ESLN,S                          ! select elements attached to nodes
    
100. EPLOT                           ! plot elements for checking/viewing
     
101. PLNSOL,TEMP, ,0,                ! plot nodal solution, temperature
     
102. /AUTO, 1      $/REP
     
103. ALLSEL,ALL                         ! select everything  
     
104. /VSCALE,1,1,0                   ! set scaling of vectors for vector plot
     
105. PLVECT,TF, , , ,VECT,ELEM,ON,0  ! produce thermal flux plot
     
106. /VSCALE,1,1,0                   ! set scaling of vectors for vector plot
     
107. PLVECT,TG, , , ,VECT,ELEM,ON,0  ! produce thermal gradient plot
     
108. /EXPAND,2,RECT,HALF,0.00001         ! expand results
     
109. ESEL,S,TYPE,,1                  ! select all type 1 elements
     
110. ALLSEL,BELOW,ELEM        ! select everything below the selected elements
     
111. NSLE,S                             ! select nodes attached to elements
     
112. PLNSOL,TEMP,,0,           ! plot nodal solution, temperature
     
113. FINISH                          ! exit the postprocessor

复制代码

yejet

Emp3:

1. /SHO,plots3,grph
   
2. /AUTO   $/GRAP,FULL
   
3. /TYP,,4      $/COM,
   
4. /COM, Preferences for GUI filtering have been set to display:
   
5. /COM,  Thermal
   
6. KEYW,PR_SET,1
   
7. KEYW,PR_THERM,1
   
8. /TITL, Nonlinear Thermal Analysis of a Transistor
   
9. /PREP7    !*  Define Geometry
   
10. RECTNG,,.01,0.03+0.01+.0025,0.03+0.01+.0025+0.0075
    
11. RECTNG,,.0225,0.03+0.01,0.03+0.01+.0025
    
12. RECTNG,,.0225,0.03,0.03+0.01
    
13. RECTNG,,.0025,,0.03
    
14. RECTNG,.0075,0.0125,,0.03
    
15. RECTNG,.0175,.0225,,0.03
    
16. AGLU,ALL
    
17. LFILLT,14,33,.0025, ,
    
18. LFILLT,33,20,0.0025, ,
    
19. LFILLT,18,34,0.0025, ,
    
20. LFILLT,34,24,0.0025, ,
    
21. AL,7,8,9
    
22. AL,10,11,33
    
23. AL,12,15,16
    
24. AL,22,23,34
    
25. ASEL,,LOC,Y,0,0.04
    
26. AADD,ALL
    
27. ET,1,PLANE77           ! 2-D 8 node thermal solid elem
    
28. KEYOPT,1,1,0           ! Consistent C matrix
    
29. KEYOPT,1,3,0           ! Planar
    
30. ET,2,SURF151           ! Thermal surface effect elem
    
31. KEYOPT,2,3,0           ! Planar
    
32. KEYOPT,2,4,0           ! Include midside node
    
33. KEYOPT,2,5,1           ! Extra node for convection
    
34. KEYOPT,2,6,0           ! Extra node is fluid temp
    
35. KEYOPT,2,8,2           ! Evaluate Hf at average temp
    
36. KEYOPT,2,9,0           ! Exclude radiation
    
37. R,1   $R,2
    
38. UIMP,1,DENS, , ,3500,
    
39. UIMP,1,KXX, , ,50,
    
40. UIMP,1,C, , ,500,
    
41. UIMP,2,DENS, , ,8900,
    
42. UIMP,2,KXX, , ,393,
    
43. UIMP,2,C, , ,385,
    
44. UIMP,3,DENS, , ,2700,
    
45. UIMP,3,KXX, , ,156,
    
46. UIMP,3,C, , ,963,
    
47. ASEL,,LOC,Y,0.0425,0.05
    
48. AATT,1,1,1
    
49. ASEL,,LOC,Y,0.04,0.0425
    
50. AATT,2,1,1
    
51. ASEL,,LOC,Y,0,0.04
    
52. AATT,3,1,1
    
53. SMRT,3
    
54. ALLSEL
    
55. AMES,ALL
    
56. LSEL,R,EXT
    
57. LSEL,R,LOC,X,.001,1
    
58. LSEL,R,LOC,Y,-1,.042
    
59. NSLL,,1
    
60. ESLN
    
61. N,5000,,-0.01
    
62. TYPE,2
    
63. REAL,2
    
64. ESURF,5000
    
65. ALLSEL
    
66. SAVE,transistor,db
    
67. /COM, Input Temp-Dependent Thermal Cond Properties
    
68. MPTGEN,1,4,50,50,   
    
69. MPDATA,KXX,1,1,53,52,47,41, , ,
    
70. MPPLOT,KXX,1,,,,,
    
71. /COM, Input Temp-Dependent Film Properties
    
72. MPTEMP,1,50,75,100,150,175,200
    
73. MPDATA,HF,4,1,18.8,17.0,16.3,14.4,12.4,6.5,
    
74. MPPLOT,HF,4,,,,,
    
75. FINI    $/SOLUTION
    
76. SOLCONTROL,ON    ! Default at ANSYS 5.5
    
77. ANTYPE,0             ! New Static analysis
    
78. TUNIF,100            ! Uniform ambient starting temperature
    
79. BFA,1,HGEN,5333333         ! Apply heat generation to transistor
    
80. /COM,  Apply Radiative Heat Flux to Lines
    
81. SFL,2,HFLUX,2400
    
82. SFL,30,HFLUX,2400
    
83. SFL,3,HFLUX,2400
    
84. ESEL,,TYPE,,2            ! Select surf. Effect elements
    
85. SFE,ALL,1,CONV,,(-4)           ! Apply Free Conv. to Surf. Eff. Elem.
    
86. ALLSEL
    
87. D,5000,TEMP,60           ! Extra node fixed at hotter ambient temp
    
88. !*  Visually verify loads
    
89. /PBC,TEMP,1
    
90. /PBF,HGEN,,1
    
91. /PSF,CONV,2
    
92. EPLO
    
93. OUTRES,ALL,ALL   ! Write results at all times for all entities
    
94. TIME,1            ! Time at end of load step = 1 second
    
95. AUTOTS,-1           ! Program Chosen ATS
    
96. NSUB,10          ! Initial number of substeps
    
97. KBC,0            ! Ramp loads
    
98. CNVTOL,HEAT, ,0.0001,2    ! Tighten convergence criterion
    
99. /TITL, Transistor Cooled by Free Convection
    
100. SAVE
     
101. SOLVE
     
102. FINISH
     
103. /POST1
     
104. SET,LIST           ! Results summary listing
     
105. SET,LAST           ! Bring in last results set
     
106. ESEL,,TYPE,,1
     
107. NSLE       
     
108. PLNS,TEMP            ! Temperature plot
     
109. ESEL,,TYPE,,2
     
110. ETABLE, ,NMISC,   5
     
111. ETABLE, ,NMISC,   7
     
112. PRETAB
     
113. ESEL,,TYPE,,1
     
114. NSLE
     
115. SET,1,3            ! Bring in results at failure point (t=0.35)
     
116. PLNS,TEMP          ! Temperature plot
     
117. ALLSEL   $FINI

复制代码

yejet

Emp4:

1. /SHO,plots4,grph
   
2. /AUTO  $/GRAP,FULL
   
3. /TYP,,4  $/COM,
   
4. /COM, Preferences for GUI filtering have been set to display:
   
5. /COM,  Thermal
   
6. KEYW,PR_SET,1
   
7. KEYW,PR_THERM,1
   
8. /TITLE, Transient Thermal Analysis of a Transistor
   
9. /PREP7    !*  Define Geometry
   
10. RECTNG,,.01,0.03+0.01+.0025,0.03+0.01+.0025+0.0075
    
11. RECTNG,,.0225,0.03+0.01,0.03+0.01+.0025
    
12. RECTNG,,.0225,0.03,0.03+0.01
    
13. RECTNG,,.0025,,0.03
    
14. RECTNG,.0075,0.0125,,0.03
    
15. RECTNG,.0175,.0225,,0.03
    
16. AGLU,ALL
    
17. LFILLT,14,33,.0025, ,   $LFILLT,33,20,0.0025, ,
    
18. LFILLT,18,34,0.0025, ,  $LFILLT,34,24,0.0025, ,
    
19. AL,7,8,9    $AL,10,11,33
    
20. AL,12,15,16  $AL,22,23,34
    
21. ASEL,,LOC,Y,0,0.04
    
22. AADD,ALL
    
23. ET,1,PLANE77           ! 2-D 8 node thermal solid elem
    
24. KEYOPT,1,1,0           ! Consistent C matrix
    
25. KEYOPT,1,3,0           ! Planar
    
26. ET,2,SURF151           ! Thermal surface effect elem
    
27. KEYOPT,2,3,0          ! Planar
    
28. KEYOPT,2,4,0          ! Include midside node
    
29. KEYOPT,2,5,1          ! Extra node for convection
    
30. KEYOPT,2,6,0          ! Extra node is fluid temp
    
31. KEYOPT,2,8,2          ! Evaluate Hf at average temp
    
32. KEYOPT,2,9,0          ! Exclude radiation
    
33. R,1   $R,2
    
34. UIMP,1,DENS, , ,3500,   $UIMP,1,KXX, , ,50,
    
35. UIMP,1,C, , ,500,       $UIMP,2,DENS, , ,8900,
    
36. UIMP,2,KXX, , ,393,    $UIMP,2,C, , ,385,
    
37. UIMP,3,DENS, , ,2700,   $UIMP,3,KXX, , ,156,
    
38. UIMP,3,C, , ,963,
    
39. ASEL,,LOC,Y,0.0425,0.05  $AATT,1,1,1
    
40. ASEL,,LOC,Y,0.04,0.0425   $AATT,2,1,1
    
41. ASEL,,LOC,Y,0,0.04
    
42. AATT,3,1,1   $SMRT,3
    
43. ALLSEL  $AMES,ALL
    
44. LSEL,R,EXT   $LSEL,R,LOC,X,.001,1
    
45. LSEL,R,LOC,Y,-1,.042
    
46. NSLL,,1   $ESLN    $N,5000,,-0.01
    
47. TYPE,2    $REAL,2
    
48. ESURF,5000    $ALLSEL   $FINI
    
49. SAVE,transistor,db
    
50. /SOLUTION
    
51. SOLCONTROL,ON             ! Default at ANSYS 5.5
    
52. ANTYPE,4             ! New Transient analysis
    
53. TRNOPT,FULL           ! Use full method
    
54. EQSLV,ITER,5            ! automatic solver and direct assembly
    
55. TUNIF,50             ! Uniform ambient starting temperature
    
56. BFA,1,HGEN,2666667           ! Apply heat generation to transistor
    
57. /COM,  Apply Radiative Heat Flux to Lines
    
58. SFL,2,HFLUX,1500    $SFL,30,HFLUX,1500
    
59. SFL,3,HFLUX,1500
    
60. ESEL,,TYPE,,2            ! Select surf. Effect elements
    
61. SFE,ALL,1,CONV,,30        ! Apply LP Fan Conv. to Surf. Eff. Elem.
    
62. ALLSEL
    
63. D,5000,TEMP,50           ! Constrain extra node temp to ambient temp
    
64. !*  Visually verify loads
    
65. /PBC,TEMP,1   $/PBF,HGEN,,1
    
66. /PSF,CONV,2   $EPLO
    
67. OUTRES,ALL,ALL            ! Write results at all times for all entities
    
68. TIME,1            ! Time at end of load step = 1 second
    
69. AUTOTS,-1         ! Program Chosen ATS
    
70. DELTIM,.01,.0025,60,0            ! INITIAL, MIN, MAX time step
    
71. KBC,0    ! Ramp loads  
    
72. !KBC, KEY — Specifies stepped or ramped loading within a load step
    
73. TINTP,,,,0.75,0.5,0.1           ! THETA=0.75, OSC=0.5, TOL=0.1
    
74. !TINTP— Defines transient integration parameters.
    
75. /COM, MONITOR,3,5000,HEAT  ! Does not work at 5.5.1
    
76. SAVE,tabular,db
    
77. /TITL, LS 1 - Transistor Activation (1 second)
    
78. SAVE   $SOLVE
    
79. TIME,300           ! Time at end of load step = 300 seconds
    
80. /TITL, LS 2 - Low Power Operation (300 seconds)
    
81. SOLVE
    
82. /TITL, LS 3 - High Power Load Ramp (302 seconds)
    
83. SFSCALE,CONV,1.7             ! Scale convection hf by 1.7 for high power
    
84. BFA,1,HGEN,2666667*2    ! Transistor heat generation
    
85. TIME,302            ! Time at end of load step = 302 seconds
    
86. SOLVE
    
87. /TITL, LS 4 - High Power Operation (900 seconds)
    
88. TIME,900            ! Time at end of load step = 900 seconds
    
89. SOLVE
    
90. /TITL, LS 5 - High Power Operation - Steady State
    
91. AUTOTS,OFF            ! Turn off automatic time stepping
    
92. NSUB,1            ! one substep
    
93. TIME,1000           ! Time at end of load step = 1000 seconds
    
94. TIMINT,OFF            ! Turn off time integration
    
95. SOLVE   $FINISH    $/POST1
    
96. SET,2           ! Bring in results at time = 300 seconds
    
97. ESEL,,TYPE,,1    $NSLE
    
98. PLNS,TEMP            ! Temperature plot
    
99. ALLSEL
    
100. SET,5            ! Bring in steady state results
     
101. PRRS             ! List reaction heat flow
     
102. FINISH    $/POST26
     
103. /TITL,
     
104. KSEL,,,,KP(0.01,0.05,0)
     
105. NSLK
     
106. *GET,N1,NODE,,NUM,MAX   ! High Temp Node Number
     
107. ALLSEL
     
108. NSOL,2,N1,TEMP, ,TEMP_MAX  ! Max temp variable
     
109. SOLU,3,DTIME, ,TIME_STP    ! Time step variable
     
110. SOLU,4,RESEIG, ,RESP_EIG   ! Response eigenvalue
     
111. PROD,5,3,4, ,OSC, , ,1,1,1,! Calculate oscillation limit
     
112. /COM, Calculate lumped mass approximation
     
113. FILLDATA,7,1, ,1,94.144,0,
     
114. EXP,8,1, , ,TERM1, , ,-.002655,-44.144,
     
115. ADD,9,7,8, ,CALC_10W, , ,1,1,1,
     
116. FILLDATA,10,1,,1,97.165,0
     
117. ! Steady-state High Power Temperature line
     
118. /GTHK,CURVE,2
     
119. /GRID,1
     
120. /AXLAB,X,Time (s)
     
121. /GTHK,AXIS,2  !/GTHK, Label, THICK — Sets line thicknesses for graph lines.
     
122. /GROPT,AXDV,1 !GROPT, Lab, KEY — Sets various line graph display options
     
123. /GROPT,AXNM,ON
     
124. /GROPT,AXNSC,1,
     
125. /GROPT,DIG1,4,
     
126. /GROPT,DIG2,0,
     
127. /GROPT,LTYP,1
     
128. /XRANGE,0,1000 !/XRANGE, XMIN, XMAX — Specifies a linear abscissa (X) scale range
     
129. /YRANGE,DEFAULT,,1
     
130. /AXLAB,Y,Temperature (C) !/AXLAB, Axis, Lab — Labels the X and Y axes on graph displays.
     
131. PLVAR,2,9,10            ! Plot Max T, Calc T, and SS T variables
     
132. PRVAR,3            ! List time step variable
     
133. /AXLAB,Y,Oscillation Limit
     
134. PLVAR,5            ! Plot Oscillation limit variable
     
135. Fini

复制代码

yejet

Emp5:

1. ! Transient Thermal Analysis of a Transistor - Tabular Loads
   
2. !TRANSIENT ANALYSIS OF TRANSISTOR USING TABULAR LOADS
   
3. !STARTING FROM tabular.db CREATED IN WORKSHOP 4
   
4. !tabular.db HAS SOLID MODEL, FEA MODEL, ALL LOADS FOR
   
5. !FIRST LOAD STEP, TRANSIENT ANALYSIS DEFINED, INITIAL T,
   
6. !SOLUTION CONTROLS ON, ITERATIVE SOLVER, OUTPUT CONTROLS,
   
7. !DELTIM, AND TIME INTEGRATION CONTROLS DEFINED
   
8. RESUME,tabular,db
   
9. !INTO THE SOLUTION PROCESSOR
   
10. /SOLU
    
11. !DELETE LOADS CURRENTLY APPLIED TO THE MODEL
    
12. BFADELE,ALL,ALL        
    
13. ! REMOVES THE HEAT GENERATION ON AREAS
    
14. SFLDELE,ALL,ALL  ! REMOVES RADIATION FLUX ON LINES
    
15. !BFADELE, AREA, Lab — Deletes body force loads on an area
    
16. SFEDELE,ALL,ALL,ALL !REMOVES THE Hf DEFINITION FOR THE
    
17. !SURFACE EFFECT ELEMENTS BUT LEAVES
    
18. !HE Tb DEFINITION(50 degrees) ON
    
19. !THE EXTRA NODE(NODE NUMBER 5000)
    
20. *DIM,TIMESET,ARRAY,3 !DEFINE ARRAY FOR TIME STEP RESET
    
21. TIMESET(1)=1.0,300,302
    
22. *DIM,HEATGEN,TABLE,5,TIME         
    
23. ! DEFINE TABLE FOR HEAT GEN.=F(T)
    
24. HEATGEN(1,0)=1.E-6,1.0,300,302,900
    
25. HEATGEN(1,1)=0.0,2666667,2666667,2*2666667,2*2666667
    
26. *DIM,CONVHF,TABLE,5,TIME           ! DEFINE TABLE FOR Hf=G(T)
    
27. CONVHF(1,0)=1.E-6,1.0,300,302,900
    
28. CONVHF(1,1)=30,30,30,51,51
    
29. *DIM,HEATFLX,TABLE,3,TIME         
    
30. ! DEFINE TABLE FOR HFLUX=Q(T)
    
31. HEATFLX(1,0)=1.E-6,1.0,900
    
32. HEATFLX(1,1)=0.0,1500,1500
    
33. /TITLE,Transistor Analysis Using Tabular Input
    
34. TIME,900  
    
35. !DEFINE COMPONENTS(NOT NECESSARY), APPLY TABULAR BCS
    
36. !TO THE COMPONENTS
    
37. ASEL,S,AREA,,1                  ! SELECT TRANSISTOR AREA
    
38. ALLSEL,BELOW,AREA  
    
39. ! SELECT ELEMENTS ASSOCIATED WITH AREA
    
40. CM,TRANAREA,ELEMENT   
    
41. !CM, Cname, Entity — Groups geometry items into a component
    
42. ALLSEL,ALL
    
43. LSEL,S,LINE,,2,3,1    ! SELECT LINES FOR RADIATION FLUX
    
44. LSEL,A,LINE,,30
    
45. CM,FLUXLINE,LINE      ! CREATE COMPONENT
    
46. ESEL,S,ENAME,,SURF151
    
47. ! SELECT ELEMENTS FOR CONVECTION
    
48. CM,CONVELEM,ELEMENT        ! CREATE COMPONENT
    
49. ALLSEL,ALL
    
50. !APPLY LOADS USING COMPONENT NAMES
    
51. BFE,TRANAREA,HGEN,1,%HEATGEN%   
    
52. ! HEAT GENERATION
    
53. SFL,FLUXLINE,HFLUX,%HEATFLX%          ! RADIATION FLUX
    
54. SFE,CONVELEM,1,CONV,,%CONVHF%          ! CONVECTION HF
    
55. !FORCE TIME STEP RESET AT LOAD CHANGE POINTS
    
56. TSRES,%TIMESET%   $SOLVE
    
57. FINISH     $/POST26
    
58. KSEL,,,,KP(0.01,0.05,0)   $NSLK
    
59. *GET,N1,NODE,,NUM,MAX
    
60. NSOL,2,N1,TEMP,,TEMP_MAX
    
61. FINI

复制代码

yejet

Emp6:

1. ! ANSYS 5.5 Heat Transfer Seminar Notes  ! Workshop #6
   
2. ! Low Pressure Gas Turbine Case Thermal Analysis
   
3. ! MUST HAVE case.db AND work6excel.txt TO RUN
   
4. RESUME,case,db    ! Supplied with seminar files
   
5. /TITLE, Low Pressure Gas Turbine Case Thermal Analysis
   
6. !*  SET PREFERENCES TO THERMAL AND FLUID/PMETH,OFF
   
7. KEYW,PR_SET,1      $KEYW,PR_THERM,1
   
8. KEYW,PR_FLUID,1   $KEYW,PR_MULTI,1
   
9. /COM,   
   
10. /COM,Preferences for GUI filtering have been set to display:
    
11. /COM,  Thermal  $/COM,  ANSYS Fluid   
    
12. /PREP7  !DEFINE THE SURF151 AND FLUID116 TYPES
    
13. ET,2,SURF151   $ET,3,FLUID116   
    
14. KEYOPT,2,3,1   $KEYOPT,2,4,1
    
15. KEYOPT,2,5,1   ! KEYOPTIONS FOR SURF151s
    
16. KEYOPT,2,6,0    $KEYOPT,2,8,2
    
17. KEYOPT,2,9,0
    
18. KEYOPT,3,1,1         ! KEYOPTIONS FOR FLUID116s
    
19. KEYOPT,3,2,1   $ETLIST, ALL
    
20. MPLIST    ! LIST PREDEFINED TEMP-DEPENDENT MPs
    
21. ! REAL SET FOR FLUID116
    
22. PI=ACOS(-1)   $R,2
    
23. R,3,,1E-6,           ! Diameter, area, # channels
    
24. !CREATE KEYPOINTS 112,113,114 ON WP
    
25. K,,16.7628783879,145.253628512,0
    
26. K,,16.4392239406,146.100950574,0
    
27. K,,16.6407907696,147.310654059,0
    
28. !CREATE LINES FOR FLUID ELEMENTS
    
29. LSTR, 112, 113  $LSTR, 113, 114
    
30. !SET ELEMENT ATTRIBUTES FOR THE LINES  
    
31. LSEL, , , ,91,92  $LATT,20,3,3,0, , ,
    
32. !SET ELEMENT DIVISIONS TO ONE FOR
    
33. !FLUID LINES  
    
34. LESIZE,ALL, , ,1,1
    
35. !MESH LINES WITH FLUID116
    
36. LMESH,ALL   $CMLIST      
    
37. ! LIST PREDEFINED LINE COMPONENTS
    
38. !CREATE SUR151S FOR ZONE 101
    
39. CMSEL,S,LZONE101
    
40. LPLOT  $NSLL,S,1  $NPLOT
    
41. TYPE,2  $MAT,1   $REAL,2
    
42. ESURF,380    ! NODE 380 IS POINT A AND EXTRA NODE
    
43. ESEL,R,ENAME,,151
    
44. !CREATE A COMPONENT FOR SURF151 ON ZONE101
    
45. CM,SURF101,ELEM
    
46. ESEL,ALL   $ESEL,U,TYPE,,2  
    
47. ! REPEAT FOR ZONE 102
    
48. CMSEL,S,LZONE102
    
49. LPLOT   $NSLL,S,1  $NPLOT   
    
50. ESURF,380   $ESEL,R,TYPE,,2  
    
51. CM,SURF102,ELEM
    
52. ESEL,ALL   $ESEL,U,TYPE,,2
    
53. !REPEAT FOR ZONE 103
    
54. CMSEL,S,LZONE103
    
55. LPLOT  $NSLL,S,1  $NPLOT
    
56. ESURF,381             ! NODE 381 IS AT POINT B
    
57. ESEL,R,TYPE,,2   $CM,SURF103,ELEM
    
58. ESEL,ALL   $ESEL,U,TYPE,,2
    
59. CMSEL,S,LZONE104
    
60. NSLL,S,1  $ NPLOT
    
61. !NSLL,Type,NKEY , Selects those nodes associated with the selected lines
    
62. ESURF,382   ! NODE 382 IS AT POINT C
    
63. ESEL,R,TYPE,,2   $CM,SURF104,ELEM
    
64. ESEL,ALL  $NSEL,ALL
    
65. !DIMENSION THE TABLE FOR HF FOR ZONE104
    
66. *DIM,HF104,TABLE,4,5,1,TIME,Y,  
    
67. !READ IN THE EXCEL SPREADSHEET
    
68. *TREAD,HF104,work6excel,txt,,4,
    
69. ALLSEL,ALL    $LPLOT
    
70. !SELECT THE LINES WHERE COUPLING IS NEEDED
    
71. FLST,5,8,4,ORDE,8
    
72. !FLST,NFIELD,NARG,TYPE,Otype,LENG
    
73. !Specifies data required for a picking operation .
    
74. FITEM,5,16 !FITEM,NFIELD,ITEM,ITEMY,ITEMZ—Identifies items chosen by a picking operation
    
75. FITEM,5,29  $FITEM,5,41  $FITEM,5,57  $FITEM,5,60  
    
76. FITEM,5,80  $FITEM,5,88  $FITEM,5,-89
    
77. LSEL,S, , ,P51X !CREATE COMPONENT OF LINES AT INTERFACE
    
78. CM,LINTERFA,LINES  $/REPLOT
    
79. NSLL,S,1   $NPLOT   
    
80. !CHECK THE DISTANCE BETWEEN NODES TO
    
81. !SET TOLERANCE FOR COUPLING
    
82. NDISTANCE,136,15   !CREATE THE COUPLING EQUATIONS
    
83. CPINTF,TEMP,0.005,    $ALLSEL,ALL
    
84. FINI  $/SOLUTION  $SOLCONTROL,ON,0
    
85. !SELECT COMPONENT SURF101
    
86. CMSEL,S,SURF101
    
87. SFE,ALL,1,CONV, , %HF101%  ! APPLY TABULAR Hf  
    
88. SFE,ALL,1,CONV,2,       !SELECT COMPONENT SURF102
    
89. CMSEL,S,SURF102
    
90. SFE,ALL,1,CONV, , %HF102%  ! APPLY TABULAR Hf
    
91. SFE,ALL,1,CONV,2,       !SELECT COMPONENT SURF103
    
92. CMSEL,S,SURF103
    
93. SFE,ALL,1,CONV, , %HF103%  ! APPLY TABULAR Hf  
    
94. SFE,ALL,1,CONV,2,       !SELECT COMPONENT SURF104
    
95. CMSEL,S,SURF104
    
96. SFE,ALL,1,CONV, , %HF104%  ! APPLY TABULAR Hf  
    
97. SFE,ALL,1,CONV,2,   
    
98. !SELECT COMPONENT LZONE105 (LINES IN ZONE105)
    
99. CMSEL,S,LZONE105        !APPLY TABULAR Hf AND Tb
    
100. SFL,ALL,CONV, %HF105% , , %TB05T09%
     
101. !SELECT COMPONENT LZONE106
     
102. CMSEL,S,LZONE106        !APPLY TABULAR Hf AND Tb  
     
103. SFL,ALL,CONV, %HF106% , , %TB05T09%
     
104. !SELECT COMPONENT LZONE107
     
105. CMSEL,S,LZONE107   !APPLY TABULAR Hf AND Tb
     
106. SFL,ALL,CONV, %HF107% , , %TB05T09%
     
107. !SELECT COMPONENT LZONE108
     
108. CMSEL,S,LZONE108    !APPLY TABULAR Hf AND Tb
     
109. SFL,ALL,CONV, %HF108% , , %TB05T09%  
     
110. !SELECT COMPONENT LZONE109
     
111. CMSEL,S,LZONE109    !APPLY TABULAR Hf AND Tb  
     
112. SFL,ALL,CONV, %HF109% , , %TB05T09%
     
113. ALLSEL,ALL      !DEFINE TABLE ARRAYS FOR INLET FLUID
     
114. !TEMPERATURE AND MASS FLOW RATES
     
115. !IN THE TWO FLUID116S
     
116. *DIM,TINLET,TABLE,4,1,1,TIME, ,
     
117. *DIM,FLOWAB,TABLE,4,1,1,TIME, ,
     
118. *DIM,FLOWBC,TABLE,4,1,1,TIME, ,
     
119. TINLET(1,0,1) = 0    $TINLET(1,1,1) = 304.33  
     
120. TINLET(2,0,1) = 3    $TINLET(2,1,1) = 870.33  
     
121. TINLET(3,0,1) = 160  $TINLET(3,1,1) = 870.33  
     
122. TINLET(4,0,1) = 163  $TINLET(4,1,1) = 304.33  
     
123. FLOWAB(1,0,1) = 0   $FLOWAB(1,1,1) = 0.001   
     
124. FLOWAB(2,0,1) = 3   $FLOWAB(2,1,1) = 0.0042  
     
125. FLOWAB(3,0,1) = 160  $FLOWAB(3,1,1) = 0.0042  
     
126. FLOWAB(4,0,1) = 163  $FLOWAB(4,1,1) = 0.001   
     
127. FLOWBC(1,0,1) = 0    $FLOWBC(1,1,1) = 0.000692
     
128. FLOWBC(2,0,1) = 3    $FLOWBC(2,1,1) = 0.002908
     
129. FLOWBC(3,0,1) = 160  $FLOWBC(3,1,1) = 0.002908
     
130. FLOWBC(4,0,1) = 163  $FLOWBC(4,1,1) = 0.000692
     
131. LPLOT     $/AUTO, 1   $/REP
     
132. !SPECIFY INLET FLUID TEMPERATURE
     
133. !AT NODE 380 AS TABULAR INPUT
     
134. D,380,TEMP,%TINLET%  
     
135. !SPECIFY MASS FLOW RATE ON FLUID116
     
136. !FROM A TO B, USING HFLUX
     
137. SFE,252,,HFLUX, ,%FLOWAB%   
     
138. SFELIS,252,HFLUX  !SPECIFY MASS FLOW RATE FROM B TO C
     
139. SFE,253,,HFLUX, ,%FLOWBC%  $SFELIS,253,HFLUX
     
140. ANTYPE,0        ! ANALYSIS TYPE STEADY-STATE
     
141. TIME,1.E-6         ! TIME AT END OF STEADY-STATE
     
142. NSUB,1       ! ONE SUBSTEP
     
143. ALLSEL
     
144. SOLVE         ! RUN STEADY-STATE
     
145. SAVE        ! SAVE THE DATABASE FOR RESTART  
     
146. FINISH   $/POST1  
     
147. PLNSOL,TEMP         ! REVIEW THERMAL CONTOURS
     
148. FINISH   $RESUME   $/SOLU   
     
149. ANTYPE,,REST  $TIMINT,ON
     
150. !DT_START = DX**2/(10 x ALPHA) = 0.05 seconds
     
151. DELTIM,0.05,0.005,10,0
     
152. KBC,0       ! RAMP LOADS
     
153. TIME,163
     
154. !DEFINE THE ARRAY TO USE FOR TIME STEP SIZE RESET
     
155. *DIM,TSTEP,ARRAY,2,1,1, , ,
     
156. TSTEP(1,1,1)=3   $TSTEP(2,1,1)=160  
     
157. TSRES,%TSTEP%    ! USE TSTEP ARRAY
     
158. OUTRES,NSOL,ALL  $SAVE
     
159. SOLVE   $FINI

复制代码

yejet

Emp7:

1. /filn,stltube     ! db created in Ch. 3 (ch3_ex.inp will create)
   
2. RESU
   
3. /PREP7  
   
4. ACLEAR,ALL        ! Clear thermal mesh
   
5. EDEL,ALL        ! Delete surface effect elements
   
6. NDEL,ALL        ! Delete extra node
   
7. ETDEL,1        ! Delete element type 1 (thermal solids)
   
8. ETDEL,2        ! Delete element type 2 (surface effect elements)
   
9. FINISH  $/SOLU   
   
10. LSCLEAR,ALL    ! Clear all thermal loads
    
11. FINISH  
    
12. /filn,stress        ! Change jobname to STRESS
    
13. /PREP7
    
14. /TITL, THERMAL-STRESS ANALYSIS OF STEEL TUBE WITH FINS
    
15. /NOPR  !/NOPR,Suppresses the expanded interpreted input data listing.
    
16. /PMETH,OFF  
    
17. KEYW,PR_SET,1   !KEYW,Keyword,KEY—Sets a keyword used by the GUI for context filtering
    
18. KEYW,PR_STRUC,1  $KEYW,PR_THERM,1
    
19. KEYW,PR_MULTI,1
    
20. /GO   $/COM,   
    
21. /COM,Preferences for GUI filtering have been set to display:
    
22. /COM,Structural   $/COM,Thermal
    
23. ET,1,PLANE82          ! 8 node structural planar solid
    
24. KEYOPT,1,3,1    ! Axisymmetric option
    
25. !INPUT Structural MPs
    
26. UIMP,1,EX, , ,28E6   $UIMP,1,DENS, , ,0.00073
    
27. UIMP,1,ALPX, , ,5E-6 $UIMP,1,NUXY, , ,0.3
    
28. !Add 0.075 Fillet Radius in Corner
    
29. LFILLT,12,15,.075  $AL,2,4,5
    
30. AADD,ALL $NUMC,ALL
    
31. TYPE,1   $MAT,1  $REAL,1  
    
32. SMRT,3   $MSHKEY,0
    
33. AMESH,ALL        ! Mesh model
    
34. NWRITE        ! Write node file (stltube.nod)
    
35. SAVE   $FINI
    
36. /FILN,stltube        ! Resume thermal model
    
37. RESU  $ALLSEL  $/POST1  
    
38. SET,LAST   ! Read in thermal results set
    
39. BFINT,stress,node,,,,,0,,0,1          ! Perform body load interp.
    
40. FINI  $/FILN,stress        ! Resume structural model
    
41. RESU  $ALLSEL   $/SOLU   
    
42. /INPUT,stltube,bfin,,,0        ! Read in body load temps (stltube.bfin)
    
43. /PBF,TEMP,1   $EPLO        ! Check temperature loads
    
44. ! Specify Analysis Settings and Other Loads
    
45. ANTYPE,0  $TREF,70
    
46. OMEGA,,2500,   $DL,1, ,SYMM
    
47. DL,8, ,SYMM    $DL,3, ,SYMM  
    
48. SFL,5,PRES,1500   $SFL,7,PRES,1500
    
49. SAVE   $SOLVE   $FINI
    
50. ! POSTPROCESS WITH TEMPS
    
51. /POST1
    
52. PLNS,S,EQV   $PLES,SDSG
    
53. PLNS,EPTH,Z  $PLNS,EPEL,Z
    
54. FINI          $/SOLU
    
55. ANTY,,REST   !Restart Solution and run w/o Temps
    
56. BFDELE,ALL,TEMP
    
57. /TITL, NO TEMPERATURE LOAD
    
58. SOLVE    $FINI
    
59. !POSTPROCESS W/O TEMPS
    
60. /POST1    SET,LAST   $PLNS,BFE,TEMP
    
61. PLNS,S,EQV  $FINI

复制代码

xsdcaifu

楼主能不能说下做的什么热分析

sysh320

我也是感觉这么好的例子应该有些说明，当然了，大家谁知道的可以写下自己的理解
有奖励哟

venture

是呀，感觉看起来好累。谁有时间看1遍再运行一下，把说明和注释加上就好了。

wschaoren

我也觉得楼主如果能够做一下这些例子的相关介绍就更好了，很感谢楼主的分享！

lover258

感谢楼主，但没有文字说明，还是感到有点麻烦。

kiddy

请问楼主有没有LS-DYNA的热分析例子啊，大哥们知不知道我下面这段热分析命令是什么问题啊，分析时总是显示
The LS-DYNA time step size should not exceed     0.651E-06
to avoid contact instabilities.  If the step size is
bigger then scale the penalty of the offending surface.
time step larger than problem time

热分析时间设置
*CONTROL_THERMAL_TIMESTEP
         1       1.0       5.0         0         0      20.0
*CONTROL_CONTACT
                   5                                                           1

*CONTROL_SOLUTION
         2
*CONTROL_THERMAL_NONLINEAR
        10       0.0       0.5
*CONTROL_THERMAL_SOLVER
         1         0         3      1E-4         0         1       0.9
*CONTROL_THERMAL_TIMESTEP
         1       1.0       5.0         0         0      20.0
*INITIAL_TEMPERATURE_SET
        10        20
        11        20
*SET_NODE_GENERAL
        10
      PART         1
*SET_NODE_GENERAL
        11
      PART         2
*BOUNDARY_TEMPERATURE_SET
        10         0        20
*BOUNDARY_TEMPERATURE_SET
        11         0        20        
************************************
*MAT_THERMAL_ISOTROPIC（钢）
         1   7.80E+6         0         0
       480      4.62
*********************************
*CONTROL_TIMESTEP
    0.0000    0.9000         0  0.00      0.00   
*CONTROL_TERMINATION
0.500E-03         0   0.00000   0.00000   0.00000
$
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
$                                 TIME HISTORY                                 $
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
$
*DATABASE_BINARY_D3PLOT
0.5000E-06
*DATABASE_BINARY_D3THDT
0.100E-07

xuruikl

期待大侠整理一下
附加点说明

xiangbeiyan

呵呵，资料是很不错，不过要是能给每个例子附加上一个简短的说明就好了，至少说明一下所给出例题的模型是怎么样的，不然看起来就太费劲了呀。