问用APDL如何实现

ForCan2008

我现在想用循环来实现10次模态分析，并将每次运算的1－5阶频率以文件的形式记录下载，请问用APDL如何实现。谢谢！最好用简单实例说明。小弟感激不尽！

ForCan2008

谢谢各位，我已经实现了。下面是代码。
/PREP7
!*************************数组定义
*DIM,dis,array,11 !建立一个11维的数组。
*DIM,NUMBER_OF_E,,10 !保存单元个数
*DIM,FREQ1,,10 !模态频率一阶
*DIM,FREQ2,,10 !模态频率二阶
*DIM,FREQ3,,10 !模态频率三阶
*DIM,FREQ4,,10 !模态频率四阶
*DIM,FREQ5,,10 !模态频率五阶
*DIM,NUM,,10
*DIM,X1,,10
*DIM,Y1,,10
!*************************进入前处理部分
WPSTYLE,,,,,,,,1  !显示工作坐标系
KEYW,PR_SET,1   
KEYW,PR_STRUC,1
!*************************参数定义
ET,1,SHELL63
ET,2,SHELL93
R,1,0.0015, , , , , ,
R,2,0.0007, , , , , ,
MPTEMP,1,0
MPDATA,EX,1,,1.93e11
MPDATA,PRXY,1,,.31
MPDATA,DENS,1,,7750
!**************************建立模型
K,1,-0.00225,0.006,,
K,2,-0.00225,-0.006,,
K,3,0,0.006,,
K,4,0,-0.006,,
K,5,0,0.00825,,
K,6,0,-0.00825,,
LSTR,       1,       2  !画线L1
LARC,1,5,3,0.00225 !画线L2
LARC,2,6,4,0.00225 !画线L3
/PNUM,LINE,1
/PNUM,AREA,1
NUMCMP,ALL  
NUMMRG,ALL, , , ,LOW
ALLSEL,ALL
LSEL,S,LOC,Z,0
LSYMM,X,ALL,2, , ,0,0  ！半边镜像
k,20,,,
k,21,,,0.198
lstr,20,21  !建立拉伸的基准线L7
ALLSEL,ALL
LSEL,S,LOC,Z,0
NUMCMP,ALL  
NUMMRG,ALL, , , ,LOW !压缩关键点
ADRAG,all,,,,,,7 !沿着线4拉伸由线1－3围城的3曲线形成面。
LDELE,7, ,,1! 删除拉伸线4
APLOT !显示面
/VIEW,1,1,2,3
/ANG,1  
/REP,FAST
!约束
ALLSEL,ALL
LSEL,S,LOC,Z,0
DL,ALL, ,ALL,
ALLSEL,ALL
!网格划分
finish

*DO,I,1,10
/PREP7
ACLEAR,ALL
ESIZE,0.001*I
amesh,all
finish
/SOLU   !进入求解模块SOLUTION   
ANTYPE, MODAL   !申明求解类型是模态分析
MODOPT,LANB,5   !使用Block Lanczos方法求解前5阶振型和频率
SOLVE   !开始求解   
FINISH      !退出后模块
/POST1  !进入后处理模块POST1        
SET, 1, 1   !读入第一阶频率和振型
SET,LIST !读取模态频率
*get,NUMBER_OF_E(i),elem,,count !获得单元数量
*get,FREQ1(I),MODE,1,FREQ,imag,,
*get,FREQ2(I),MODE,2,FREQ,imag,,
*get,FREQ3(I),MODE,3,FREQ,imag,,
*get,FREQ4(I),MODE,4,FREQ,imag,,
*get,FREQ5(I),MODE,5,FREQ,imag,,
finish
*ENDDO
/solu
*CFOPEN,result_model,xls
*VWRITE,FREQ1(1),FREQ2(1),FREQ3(1),FREQ4(1),FREQ5(1),NUMBER_OF_E(1)
(F8.0,F8.2,F8.2,F8.2,F8.2,F8.0)
*CFCLOS
finish

sunlb

稍微看了你的程序，好像10次模态分析是重复的，仅网格划分不同，重复计算的意义何在？

模态提取方法用的是lanb，

我做了些计算，对系统矩阵不平衡的问题，好像必须用unsymm或damp来做

有没有这方面的经验？用damp提取的固有频率不能用这句命令读取

*get,freq,mode,1,freq

QQ:63958343，欢迎进一步讨论

skybluearrow

谢谢，指点

ForCan2008

谢谢！我是刚学习，好多东西还不懂。

xueyi

楼主解决了我一直想解决的问题，这样可以方便提取各阶频率。
楼主的循环的意图应是查看壳单元网格大小对模态分析结果的影响，不知对否？
有两个问题：
一、不知楼主结论如何？壳单元网格大小对模态分析结果的影响
二、壳单元的假设（其长厚比）不知需不需要在画网格时考虑
请指教。还有一点想法就是模态分析网格不用太密，因为此时只是看振型，只有看应力时才需要。

ForCan2008

就是，谢谢楼上的意见。主要的目的是学习，为以后进行工程分析打基础。