一个典型的问题：梁的正弦加载的瞬态分析

powerlong

模型描述：
1）悬臂梁顶端施加X向正弦变化的载荷，进行瞬态动力求解；
2）单元为beam188；
3）/post26中能提取末端的位移结果。

模型如下图，已经通过模态、谐响应计算(如下图)，但瞬态计算总是无法得到理想的结果。

问题：
我认为，梁顶端的位移输出为一正弦曲线，但ANSYS计算结果的时间-位移历程总是无法得到正弦曲线，不知是何原因？我觉得是力载荷的加载有问题，主要出现在激励频率的确定上，但总是调试不出来。请高手指点。

命令流：
/FILNAME,BTSanlysis
/UNITS,SI
/TITLE,Bond Tool计算

D=3e-3!直径
L=15e-3 !长度
S=3.141593*(D/2)*(D/2)!截面积
I=3.141593*D*D*D*D/64

/PREP7!建模
ET,1,BEAM188!梁单元 3，188，189
MP,EX,1,620.53E9!弹性模量
MP,DENS,1,14880
MP,PRXY,1,0.29
!MP,DAMP,1,0.0085

secnum,1
sectype,1,beam,CSOLID
secdata,D/2,10,3!

N,1,0,0
N,21,0,-L
FILL,1,21
E,1,2
EGEN,20,1,1,1,1

/PNUM,NODE,1!图示节点及编号
/PNUM,ELEM,1!图示单元及编号
EPLOT!显示单元
FINISH

/SOLU
ANTYPE,2!模态分析
EQSLV,SPAR
MXPAND,100, , ,1
LUMPM,0
PSTRES,0
MODOPT,LANB,100,5000,100000, ,OFF

OUTPR,BASIC,ALL
d,1,uy,,,,,uz,rotx,roty,rotz
SOLVE
FINISH
/POST1

!做谐响应分析
/SOLU
ANTYPE,HARMIC! HARMONIC RESPONSE ANALYSIS
HROUT,OFF! Print results as amplitudes and phase angles
HROPT,full

OUTPR,BASIC,1
harfrq,5000,100000! FREQUENCY RANGE FROM 0 TO 7.5 HZ
NSUBST,200! 30 INTERVALS WITHIN FREQ. RANGE
KBC,1! STEP BOUNDARY CONDITION

d,1,uy,,,,,uz,rotx,roty,rotz!very important!!
!D,1,UX,10
F,1,FX,200

ALLS
SOLVE
FINISH

/POST26
NSOL,2,21,U,X,UX! STORE UX DISPLACEMENT OF NODE 21作为变!量2
!ESOL,3,21,,SMISC,1,F1! STORE 摩擦力FORCE F1 OF ELEMENT 1 AS VARIABLE 3
!由K1引起的弹性力F1.
!PRVAR,2,3! PRINT VARIABLES 2 AND 3
/GRID,1! TURN GRID ON
/AXLAB,Y,DISP! Y AXIS LABEL AS DISP
/GTHK,CURVE,2! CURVE LINES THICKNESS RATIO OF 2
PLVAR,2

!做瞬态分析
/SOLu
antype,trans
trnopt,full
outpr,all,all
outres,all,all
!alphad,0.014
!betad,0.000092

autots,on
kbc,1
!tintp,,0.25,0.5,0.5
d,1,uy,,,,,uz,rotx,roty,rotz

*do,i,1,2000,1
t=i/100000
time,t
nsubst,50
!施加约束条件
Pressure=10*sin(2*3.14159*91743*t) !如何设置激励力的频率？f为其中的FX方 向振动的固有频率？
F,1,FX,Pressure

solve
lswr,i
*enddo
fini

/POST26
NSOL,2,21,U,X,UX! STORE UX DISPLACEMENT OF NODE 21作为变!量2
!ESOL,3,21,,SMISC,1,F1! STORE 摩擦力FORCE F1 OF ELEMENT 1 AS VARIABLE 3
!由K1引起的弹性力F1.
!PRVAR,2,3! PRINT VARIABLES 2 AND 3
/GRID,1! TURN GRID ON
/AXLAB,Y,DISP! Y AXIS LABEL AS DISP
/GTHK,CURVE,2! CURVE LINES THICKNESS RATIO OF 2
PLVAR,2

powerlong

模型为：

powerlong

谐响应结果应该正确，在所分析的频率范围内有2阶FX方向的固有频率被激发出来。

powerlong

梁的末端位移响应如图，可得这明显不对。我认为其位移也是正弦曲线。各位提示一下，如何修改？如何设置激励力？

realyyy

有点晕，等我研究研究先。

ljt34

[em02][em03]

jiangxuchu

我也碰到这种问题，也是不知怎么加载正弦载荷？希望有位高手指点一下

TNC

ansys对于正弦载荷可以有两种处理方法
一是用谐响应分析，把正弦载荷当做向量来处理
二是瞬态分析

jiangxuchu

但是在瞬态分析时，它需要设置时间载荷步，而且它只默认斜坡载荷函数和Step载荷函数，一旦碰到简谐载荷函数，或者其它连续的函数载荷，在加载时怎样设置时间载荷步？请指教！！

linlin820

　　可以用table加载

　　

[此贴子已经被作者于2006-3-18 8:52:54编辑过]

kslumeiyu

[em01]太好了

alwaysfly

下面一个用beam3梁单元来施加正弦荷载进行瞬态分析，希望对你有帮助
!用beam3计算
finish
/clear
/title,the transient analysis of a beam use of beam3
/prep7
et,1,beam3
R,1,0.05*0.006,1/12*0.05*0.006**3,0.006, , , ,
mp,ex,1,2.11e11
mp,dens,1,7800
mp,prxy,1,0.2
k,1
k,2,1
lstr,1,2
lesize,1,,,20
lmesh,all
finish
/solu
antype,2
dk,1,all
d,all,uz
modopt,lanb,3,0,0, ,off
mxpand,3, , ,0
outpr,basic,1,
solve
finish
/post1
set,list,2
finish
!***************************瞬态分析
/solu
antype,4
trnopt,full
time,0
autots,0
deltim,0.01, , ,1
kbc,0
alphad,1.0926529, !由计算得知
betad,0.0001737,
outpr,basic,all,
*do,i,1,400,1 !计算到4秒
time,0.01*i
autots,-1
deltim,0.01, , ,1
kbc,0
fn=sin(15*i*0.01)
fk,2,fy,-fn
solve
*enddo
finish
/post26
file,'file','rst','.'
nsol,2,2,u,y, uy_2
xvar,1
plvar,2,
PRVAR,2,

楼主用这个试一试
结果应该可以

sysh320

　　我也研究研究，谢谢楼主!

realyyy

学习了！很好！

5dehaoma

谢谢了