谐响应分析中，怎么输出一个频段的结果？

huhust

下面程序是谐响应分析，外激励频率一定的情况下，计算气膜刚度和阻尼系数
如果我要输出一个频段的结果，应该怎么办？应该是个后处理的问题，弄了几天弄不出结果，请高手帮忙。谢谢啦！

/batch,list
/PREP7
/title, Damping and Squeeze film stiffness calculations for a rigid
/com,  plate with holes
/com    uMKS units

ET, 1,136,1    ! 4-node option, High Knudsen Number
ET, 2,138,1    ! Circular hole option, Hugh Knudsen Number

s_l=100                        ! Half Plate length (um)
s_l1=60                        ! Plate hole location
s_w=20                          ! Plate width
s_t=1                          ! Plate thickness
c_r=3                          ! Hole radius
d_el=2                          ! Gap
pamb=.1                           ! ambient pressure (MPa)
visc=18.3e-12                  ! viscosity kg/(um)(s)
velo=2000                      ! arbitrary velocity (um/s)
freq=150000                    ! Frequency (Hz.)
pi=3.14159
omega=2*pi*freq                         ! Frequency (rad/sec)
pref=.1                        ! Reference pressure (MPa)
mfp=64e-3                           ! mean free path (um)
Knud=mfp/d_el                  ! Knudsen number

mp,visc,1,visc                     ! Dynamic viscosity gap
mp,visc,2,visc                       ! Dynamic viscosity holes

r,1,d_el,,,pamb                       ! Real constants - gap
rmore,pref,mfp

r,2,c_r,,,pamb                       ! Real constants - hole
rmore,pref,mfp

! Build the model

rectng,-s_l,s_l,-s_w,s_w        ! Plate domain
pcirc,c_r                        ! Hole domain
agen,3,2,,,-s_l1/3
agen,3,2,,,s_l1/3
ASBA, 1, all

TYPE, 1
MAT, 1
smrtsize,4
AMESH, all                        ! Mesh plate domain                                    


! Begin Hole generation
*do,i,1,5
nsel,all
*GET, numb, node, , num, max    ! Create nodes for link elements
N, numb+1,-s_l1+i*s_l1/3,,
N, numb+2,-s_l1+i*s_l1/3,, s_t
TYPE,2
MAT, 2
REAL,2
NSEL, all
E, numb+1, numb+2                  ! Define 2-D link element
ESEL, s, type,,1
NSLE,s,1
local,11,1,-s_l1+i*s_l1/3
csys,11
NSEL,r, loc, x, c_r      ! Select all nodes on the hole circumference
NSEL,a, node, ,numb+1
*GET, next, node, , num, min
CP, i, pres, numb+1, next
nsel,u,node, ,numb+1
nsel,u,node, ,next
CP, i, pres,all            !Coupled DOF set for constant pressure
csys,0                                 
*enddo
! End hole generation

nsel,s,loc,x,-s_l
nsel,a,loc,x,s_l
nsel,a,loc,y,-s_w
nsel,a,loc,y,s_w
nsel,r,loc,z,-1e-9,1e-9
d,all,pres                ! Fix pressure at outer plate boundary
nsel,all

esel,s,type,,2
nsle,s,1
nsel,r,loc,z,s_t
d,all,pres,0              ! P=0 at top of plate
dlist,all

allsel

bfe,all,flue,,velo           ! Apply arbitrary velocity   
    ! BFE, ELEM, Lab, STLOC, VAL1, VAL2, VAL3, VAL4
    ! Defines an element body force load.  FLUE: fluence

fini

finish
/solu
antyp,harm           ! Full Harmonic analysis
harfrq,freq            ! Defines the frequency range in the harmonic response analysis.
solve
finish
/post1
esel,s,type,,1
! ESEL, Type, Item, Comp, VMIN, VMAX, VINC, KABS
set,1,1
    ! SET, Lstep, Sbstep, Fact, KIMG, TIME, ANGLE, NSET, ORDER
    ! Defines the data set to be read from the results file.
        ! KIMG: Used only with results from complex analyses.
        ! 0  —  Store real part of complex solution.
    ! 1  —  Store imaginary part.

etable,presR,pres          ! extract "Real" pressure
    ! ETABLE, Lab, Item, Comp
    ! Fills a table of element values for further processing.

etable,earea,volu
smult,forR,presR,earea      ! compute "Real" force
    ! SMULT, LabR, Lab1, Lab2, FACT1, FACT2
    ! LabR = (FACT1 x Lab1) x (FACT2 x Lab2)
    ! Forms an element table item by multiplying two other items.
ssum    ! Calculates and prints the sum of element table items.
*get,Fre,ssum,,item,forR
    ! *GET, Par, Entity, ENTNUM, Item1, IT1NUM, Item2, IT2NUM
    ! Par是存储提取项的参数名；
    ! Entity是被提取项目的关键字，有效地关键字是NODE, ELEM, KP, LINE, 　　AREA, VOLU, PDS等；
    ! ENTNUM是实体的编号（若为０指全部实体）；
    ! Item1是指某个指定实体的项目名．例如，如果Entity是ELEM，那么Item1
    ! Retrieves a value and stores it as a scalar parameter or part of an array parameter.

set,1,1,,1
etable,presI,pres          ! extract "Imaginary" pressure
smult,forI,presI,earea      ! compute "Imaginary" pressure
ssum
*get,Fim,ssum,,item,forI



K=abs(Fim*omega/velo)      ! Compute equivalent stiffness
C=abs(Fre/velo)            ! Compute equivalent damping

/com, ******* Equivalent stiffness  ************************
*stat,K
/com, ******* Equivalent damping  **************************
*stat,C
finish

cactus0711

到 时间历程后处理 中看看
应该有很多办法

16443

在outres设置中可以设置。