塔式结构瞬态响应分析

chivalry

小弟初次做结构的瞬态分析，在读入荷载步进行分析时，总是出现 *** WARNING ***
No constraints have been defined using the D command.  ，导致节点位移不收敛。实在不知如何解决，请各位高手帮帮忙。
命令流如下：
FINISH
/CLEAR
/FILNAME,ANALYSIS OF WIND TURBINE AND FOUNDATION
/TITLE,MODAL ANALYSIS OF WIND TURBINE AND FOUNDATION

/PREP7
ET,1,SHELL63
ET,2,SOLID45
MP,EX,1,2.0E11
MP,PRXY,1,0.3
MP,DENS,1,8000
MP,EX,2,2.0E11
MP,PRXY,2,0.3
MP,DENS,2,570

!指定壳单元实常数
R,1,0.026
R,2,0.020
R,3,0.014

!建立几何模型
K,1,1.987,0
K,2,1.789,18.2
K,3,1.492,40.6
K,4,1.591,63
K,5,0,0
K,6,0,63
*DO,I,1,3,1
  L,I,I+1
*ENDDO
*DO,I,1,3
  AROTAT,I,,,,,,5,6
*ENDDO
WPAVE,-1.5,65,0
BLOCK,-5,5,-2,2,-2,2

!分配实参和材料属性
LSEL,S,LINE,,4,6,1
LSEL,A,LINE,,1,3,1
LSEL,A,LINE,,15,17,1
LSEL,A,LINE,,26,28,1
LESIZE,ALL,,,40
LSEL,INVE
LESIZE,ALL,,,6
ASEL,S,AREA,,1,4,1
TYPE,1
REAL,1
MAT,1
ASEL,S,AREA,,5,8,1
TYPE,1
REAL,2
MAT,1
ASEL,S,AREA,,9,12,1
TYPE,1
REAL,3
MAT,1
ASEL,S,AREA,,1,12,1
AMESH,ALL
ALLSEL,ALL
VSEL,ALL
TYPE,2
MAT,2
VMESH,ALL

!施加约束
ALLSEL,ALL
NUMMRG,ALL
NUMCMP,ALL
NSEL,S,LOC,Y,0
D,ALL,ALL,0
ALLSEL,ALL
NSEL,S,LOC,Y,63
NSEL,R,LOC,Z,-1.5,1.5
NSEL,R,LOC,X,-1.5,1.5
CP,1,ALL,ALL
ALLSEL,ALL

!读入荷载数据，以数组形式储存
......
!定义载荷曲线
*DO,TN,1,2
  ALLSEL,ALL
  TIME,0.25*TN
  AUTOTS,OFF
  DELTIM,0.05
  KBC,0
  FDELE,ALL,ALL
  *DO,I,1,6
    ZL=5+(I-1)*10
    *DO,J,1,24
    YL=-165+(J-1)*15
    CSYS,5
    NSEL,S,LOC,Z,ZL
    NSEL,R,LOC,Y,YL  
    NROTAT,ALL
    F,ALL,FX,-WF(I,J,TN)
    *ENDDO
  *ENDDO
   *DO,J,1,24
     YL=-165+(J-1)*15
     CSYS,5
     NSEL,S,LOC,Z,62
     NSEL,R,LOC,Y,YL
     NROTAT,ALL
     F,ALL,FX,-WF(7,J,TN)
   *ENDDO
   CSYS,0  
   NSEL,S,LOC,Y,65
   NSEL,R,LOC,X,-6.5
   NSEL,R,LOC,Z,0
   F,ALL,FX,WFBLADE(TN)
   LSWRITE,TN
*ENDDO
FINISH

!求解时程响应
/SOLU
ANTYPE,TRANS !瞬态响应求解
TIMINT,ON,ALL
TRNOPT,FULL
OUTPR,NSOL
OUTRES,NSOL,ALL
ALLSEL,ALL
LSSOLVE,1,2,1
FINISH

16443

No constraints have been defined using the D command.
自己检查边界条件

chivalry

模型的约束只有一处，即NSEL,S,LOC,Y,0 ；D,ALL,ALL。读取荷载步前我检查过节点约束的，但是运算后就没约束了。

chivalry

为什么按照静力加载就不会出现这样警告？

chivalry

我后来用循环的方法代替荷载步读取求解的过程，没出现上述问题。

chivalry

终于解决了。看了HELP才知道，自重荷载作为第一步加载时是不能设置模型节点约束的，后续荷载步才能加上。
...
ACEL,,9.81        ! Initial Y-direction acceleration
TIME,.001         ! Small time interval
NSUBST,2          ! Two substeps
KBC,1             ! Stepped loads
!  The structure must be unconstrained in the initial load step, or
!  else the initial acceleration specification will have no effect.
DDELE, ...        ! Remove displacement constraints (if appropriate)
LSWRITE           ! Write load data to load step file (Jobname.S01)

!  Transient solution
TIME, ...         ! Realistic time interval
NSUBST, ...       ! Use appropriate time step
KBC,0             ! Ramped loads (if appropriate)
D, ...            ! Constrain structure as desired
!  Continue with normal transient solution procedures
LSWRITE           ! Write load data to load step file (Jobname.S02)

cxh@

help的什么地方有？请告诉一下

cxh@

找到了！谢谢  ！