瞬态分析的问题

watcher

ANSYS用的不熟，试着建模进行瞬态分析，但是求解过程中一直提示警告，说是**节点没有被选择，有很多，无法继续求解。下面是我用的命令流，希望大侠指点迷津。

!Build the Model
/CLEAR,START
/FILNAM,TEST,0   !任务名
/TITLE,TEST
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!前处理!!!!!!!!!!!!!!!!!!!!!!!!
/PREP7    !进入前处理
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!几何常数
L=0.200    !长度(m)
H=0.020    !高度(m)
W=0.200    !宽度(m)
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!几何模型
numstr,kp,1   !对应标签的起始编号
numstr,node,1   !对应标签的起始编号
numstr,line,1   !对应标签的起始编号
numstr,area,1   !对应标签的起始编号
numstr,volu,1   !对应标签的起始编号
numstr,elem,1   !对应标签的起始编号
K,1,0,0,0   !定义点
K,2,0,W,0   !定义点
K,3,L,W,0   !定义点
K,4,L,0,0   !定义点
K,5,0,0,H   !定义点
K,6,0,W,H   !定义点
K,7,L,W,H   !定义点
K,8,L,0,H   !定义点
V,1,2,3,4,5,6,7,8  !定义体
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!设置单元
ET,1,SOLID45,0,0,0,0,0,0 !选择单元类型
!R,,,,,    !设置单元常数
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!设置材料参数
MP,EX,1,2000   !设置材料弹性模量(X方向)
MP,EY,1,2000   !设置材料弹性模量(Y方向)
MP,EZ,1,2000   !设置材料弹性模量(Z方向)
MP,PRXY,1,0.32   !设置材料最大泊松比(XY方向)
MP,PRYZ,1,0.32   !设置材料最大泊松比(YZ方向)
MP,PRXZ,1,0.32   !设置材料最大泊松比(XZ方向)
!MP,NUXY,1,0.32   !设置材料最小泊松比(XY方向)
!MP,NUYZ,1,0.32   !设置材料最小泊松比(YZ方向)
!MP,NUXZ,1,0.32   !设置材料最小泊松比(XZ方向)
MP,GXY,1,500   !设置材料剪切模量(XY方向)
MP,GYZ,1,500   !设置材料剪切模量(YZ方向)
MP,GXZ,1,500   !设置材料剪切模量(XZ方向)
MP,DENS,1,7800   !设置材料质量密度
VATT,1,1,1   !将单元、材料等链接到模型
MSHARP,0,3D   !设置网格形状
!MSHKEY,   !设置网格类型(自由/映射)
ESIZE,0.01   !设置单元的边长
VMESH,ALL   !划分单元
FINISH    !退出前处理PREP7
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!求解问题!!!!!!!!!!!!!!!!!!!!!!
/SOLU    !进入求解器
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!求解类型
ANTYPE,TRANS   !问题类型:瞬态分析
TRNOPT,FULL   !求解方式:FULL
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!载荷/约束
NSEL,S,LOC,X,0,0,1,1  !选择节点
NSEL,A,LOC,X,L,L,1,1  !选择节点
NSEL,A,LOC,Y,0,0,1,1  !选择节点
NSEL,A,LOC,Y,W,W,1,1  !选择节点
CM,MYBC,NODE   !设定点集
D,ALL,ALL,0   !定义约束
NSEL,S,LOC,Z,0,0,1,1  !选择节点
NSEL,U,LOC,X,0,L/2-0.002,1,1 !选择节点
NSEL,U,LOC,X,L/2+0.002,L,1,1 !选择节点
NSEL,U,LOC,Y,0,W/2-0.002,1,1 !选择节点
NSEL,U,LOC,Y,W/2+0.002,W,1,1 !选择节点
CM,MYFC,NODE   !设定点集
*DIM,FFF,TABLE,8,1,1,TIME
FFF(0,1)=0,0.5,1,1.001,1.002,1.003,1.5,2
FFF(1,1)=0,0,0,10000,10000,0,0,0
F,ALL,Fz,%FFF%,,,
ALPHAD,0.01   !定义质量阻尼乘数
BETAD,0.01   !定义刚度阻尼乘数
AUTOTS,ON   !开启自动变步长
DELTIM,0.001,0.0001,0.01,ON !设置步长变化范围
TIMINT,ON
OUTRES,ALL,LAST   !结果输出设置
LSWRITE    !写入载荷步
SAVE
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!求解
LSSOLVE,1,1                《-这一步无法完成:(
FINISH    !退出求解器
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!后处理!!!!!!!!!!!!!!!!!!!!!!

jxxansys

在LSWRITE命令前
加time命令、加alls

[ 本帖最后由 jxxansys 于 2009-9-23 16:13 编辑 ]

watcher

问题已解决，呵呵，非常感谢:victory: